Tech-invite3GPPspaceIETFspace
959493929190898887868584838281807978777675747372717069686766656463626160595857565554535251504948474645444342414039383736353433323130292827262524232221201918171615141312111009080706050403020100
in Index   Prev   Next

RFC 3108

Conventions for the use of the Session Description Protocol (SDP) for ATM Bearer Connections

Pages: 110
Proposed Standard
Errata
Part 4 of 4 – Pages 83 to 110
First   Prev   None

Top   ToC   RFC3108 - Page 83   prevText

6. List of Parameters with Representations

This section provides a list of the parameters used in this document, and the formats used to represent them in SDP descriptions. In general, a "-" value can be used for any field that is not specified, is inapplicable or is implied. PARAMETER MEANING REPRESENTATION <username> User name Constant "-" <sessionID> Session ID Up to 32 decimal or hex digits <version> Version of "0" or 10 decimal digits SDP descriptor <networkType> Network type Constant "ATM" for ATM transport <addressType> Address type String values: "NSAP", "E164", "GWID", "ALIAS" <address> Address "NSAP": 40 hex digits, dotted "E164": up to 15 decimal digits "GWID": up to 32 characters "ALIAS": up to 32 characters <sessionName> Session name Constant "-" <startTime> Session start "0" or 10 decimal digits time <stopTime> Session stop Constant "0" time <vcci> Virtual Circuit Decimal or hex equivalent Connection of 16 bits Identifier <ex_vcci> Explicit "VCCI-" prefixed to <vcci> representation of <vcci> <bcg> Bearer Connection Decimal or hex equivalent Group of 8 bits
Top   ToC   RFC3108 - Page 84
<ex_bcg>            Explicit             "BCG-" prefixed to <bcg>
                    representation
                    of <bcg>

<portId>            Port ID              Hex number of up to 32 digits


<ex_portId>         Explicit             "PORT-" prefixed to <portId>
                    representation
                    of <portId>

<vpi>               Virtual Path         Decimal or hex equivalent
                    Identifier           of 8 or 12 bits

<ex_vpi>            Explicit             "VPI-" prefixed to <vpi>
                    representation
                    of <vpi>

<vci>                Virtual Circui t    Decimal or hex equivalent
                     Identifier          of 16 bits

<ex_vci>             Explicit            "VCI-" prefixed to <vci>
                     representation
                     of <vci>

<vpci>               Virtual Path        Decimal or hex equivalent
                     Connection          of 16 bits
                     Identifier

<ex_vpci>            Explicit            "VPCI-" prefixed to <vpci>
                     representation
                     of <vpci>

<cid>                Channel             Decimal or hex equivalent
                     Identifier          of 8 bits

<ex_cid>             Explicit            "CID-" prefixed to <cid>
                     representation
                     of <cid>

<payloadType>        Payload              Decimal integer 0-127
                     Type

<transport>          Transport            Values listed in
                                          Table 1.

<profile>            Profile              Decimal integer 1-255
Top   ToC   RFC3108 - Page 85
<eecid>              End-to-end           Up to 8 hex digits
                     Connection
                     Identifier

<aalType>            AAL type             String values:
                                          "AAL1","AAL1_SDT","AAL1_UDT",
                                          "AAL2", "AAL3/4",
                                          "AAL5", "USER_DEFINED_AAL"

<asc>               ATM service           String values:
                    category defined      "CBR", "nrt-VBR", "rt-VBR",
                    by the ATMF           "UBR", "ABR", "GFR"

<atc>               ATM transfer          String values:
                    capability            "DBR","SBR","ABT/IT","ABT/DT",
                    defined by the        "ABR"
                    ITU

<subtype>            <asc>/<atc>          Decimal integer 1-10
                     subtype

<qosClass>           QoS Class            Decimal integer 0-5

<bcob>               Broadband Bearer     Decimal or hex representation
                     Class                of 5-bit field

<eetim>              End-to-end timing    String values: "on",
                     required             "off".

<stc>                Susceptibility       Decimal equivalent of
                     to clipping          a 2-bit field

<upcc>               User plane           Decimal equivalent of
                     connection           a 2-bit field
                     configuration

<directionFlag>      Direction Flag       String values: "f", "b",
                                          "fb"

<cdvType>            CDV type             String values:
                                          "PP", "2P"

<acdv>               Acceptable CDV       Decimal equivalent
                                          of 24-bit field

<ccdv>               Cumulative CDV       Decimal equivalent
                                          of 24-bit field
Top   ToC   RFC3108 - Page 86
<eetd>               End-to-end transit   Decimal equivalent
                     delay                of 16-bit field


<cmtd>               Cumulative transit   Decimal equivalent
                     delay                of 16-bit field

<aclr>               Acceptable           Decimal equivalent
                     Cell Loss Ratio      of 8-bit field

<clpLvl>             CLP level            String values:
                                          "0", "0+1"

<pcr>                Peak                 Decimal
                     Cell Rate            equivalent of a 24-bit field.

<scr>                Sustained            Decimal
                     Cell Rate            equivalent of a 24-bit field

<mbs>                Maximum              Decimal
                     Burst Size           equivalent of 16-bit field

<cdvt>               CDVT                 Decimal equivalent of 24-bit
                                          field.

<mcr>                Minimum              Decimal
                     Cell Rate            equivalent of a 24-bit field

<mfs>                Maximum              Decimal
                     Frame Size           equivalent of a 16-bit field

<fd>                 Frame Discard        String Values:
                     Allowed              "on", "off"

<te>                 CLP tagging          String Values:
                                          "on", "off"

<nrm>                NRM                  Decimal/hex equivalent
                                          of 3 bit field

<trm>                TRM                  -ditto-

<cdf>                CDF                  -ditto-

<adtf>               ADTF                 Decimal/Hex  equivalent
                                          of 10 bit field
Top   ToC   RFC3108 - Page 87
<ficr>               Forward Initial      Decimal equivalent of
                     Cell Rate            24-bit field

<bicr>               Backward Initial     Decimal equivalent of
                     Cell Rate            24-bit field

<ftbe>               Forward Transient    Decimal equivalent of
                     Buffer Exposure      24-bit field

<btbe>               Backward Transient   Decimal equivalent of
                     Buffer Exposure      24-bit field

<crmrtt>             Cumulative RM        Decimal equivalent of
                     round-trip time      24-bit field
                     (Microseconds)

<frif>               Forward rate         Decimal integer
                     increase factor      0 -15

<brif>               Backward rate        Decimal integer
                     increase factor      0 -15

<frdf>               Forward rate         Decimal integer
                     decrease factor      0 -15

<brdf>               Backward rate        Decimal integer
                     decrease factor      0 -15

<bearerType>         Bearer Type          String Values:
                                          "PVC", "SVC", "CID"

<localInitiation>    Local Initiation      String values:
                                           "on", "off"

<sci>                Screening Indication  Decimal or hex
                                           equivalent of 4  bits.

<lsn>                Leaf Sequence Number  Decimal or hex
                                           equivalent of 32 bits.

<cdStd>              Coding standard for          Decimal or hex
                     connection scope             equivalent of 2 bits.
                     selection IE
                     Definition: UNI 4.0 [5]

<conScpTyp>          Type of connection scope     Decimal or hex
                     Definition: UNI 4.0 [5]      equivalent of 4 bits
Top   ToC   RFC3108 - Page 88
<conScpSel>          Connection scope selection   Decimal or hex
                     Definition: UNI 4.0 [5]      equivalent of 8 bits

<cacheEnable>        Enable SVC caching           String values: "on",
                                                  "off"

<cacheTimer>        Timer for cached SVC       Decimal or hex equivalent
                    deletion                   of 32-bit field

<bearerSigIEType>   Bearer Signaling IE Type      2 hex digits

<bearerSigIELng>    Bearer Signaling IE Length    1-4 hex digits

<bearerSigIEVal>    Bearer Signaling IE Value     Even number of hex
                                                  digits, 2-512

<appClass>          Application                String values:
                    specification              "itu_h323c","af83",
                                               "AAL5_SSCOP",
                                               "itu_i3661_unassured",
                                               "itu_i3661_assured",
                                               "itu_i3662",
                                               "itu_i3651", "itu_i3652",
                                               "itu_i3653", "itu_i3654",
                                               "FRF5", "FRF8","FRF11",
                                               "itu_h2221"

<oui>               Organizationally         1 to  6 hex digits
                    Unique Identifier

<appId>             Application Identifier   1 to 8 digits

<cbrRate>           CBR Rate                 Two hex digits.

<sbc>               Subchannel Count         T1: Decimal integer 1-24
                                             or hex equivalent
                                             E1: Decimal integer 1-31
                                             or hex equivalent

<clkrec>             Clock Recovery          String values:
                     Method                  "NULL", "SRTS",
                                             "ADAPTIVE"

<fecEnable>          Forward Error           String values:
                     Correction Enable       "NULL", "LOSS_SENSITIVE"
                                             "DELAY_SENSITIVE"
Top   ToC   RFC3108 - Page 89
<partialFill>        Partial Fill            Decimal integer 1-48
                                             or hex equivalent

<structureEnable>    Structure Present       String values:
                                             "on", "off"

<blksz>              Block Size              Decimal or hexadecimal
                                             equivalent of 16 bits

<cpcs>              Maximum                  AAL5: Decimal or hex
                    CPCS SDU size            equivalent of 16 bits
                                             AAL2: 45 or 64, decimal
                                             or hex representation

<cidLowerLimit>     AAL2 CID lower limit     Decimal integer 8-255
                                             or hex equivalent

<cidUpperLimit>     AAL2 CID upper limit     Decimal integer 8-255
                                             or hex equivalent


<timerCU>           Timer, combined use      Integer decimal; range
                    (microseconds)           determined by application.
                                             Use decimal equivalent of
                                             32 bits.

<simplifiedCPS>     Simplified CPS [52]      String values:
                                             "on", "off"

<fSDUrate>          Forward SDU rate         Decimal equivalent of
                    (bits per second)        24-bit field

<bSDUrate>          Backward SDU rate        Decimal equivalent of
                    (bits per second)        24-bit field

<ted>               Transmission Error       String values:
                    Detection Enable         "on", "off"

<rastimer>          SSSAR reassembly         Integer decimal,
                    (microseconds)           Range determined by
                                             application.  Use decimal
                                             equivalent of 32 bits.

<fsssar>            Maximum SSSAR-SDU        Decimal 1- 65568
                    size, forward            or hex equivalent
                    direction
Top   ToC   RFC3108 - Page 90
<bsssar>            Maximum SSSAR-SDU        Decimal 1- 65568
                    size, backward           or hex equivalent
                    direction

<fsscopsdu>         Maximum SSCOP-SDU        Decimal 1- 65528
                    size, forward            or hex equivalent
                    direction

<bsscopsdu>         Maximum SSCOP-SDU        Decimal 1- 65528
                    size, backward           or hex equivalent
                    direction

<fsscopuu>          Maximum SSCOP-UU         Decimal 1- 65524
                    field size, forward      or hex equivalent
                    direction

<bsscopuu>          Maximum SSCOP-UU         Decimal 1- 65524
                    field size, backward     or hex equivalent
                    direction

<sap>               Service Access           String values:
                    Point                    "AUDIO", "MULTIRATE"

<circuitMode>       Circuit Mode             String values:
                    Enable                   "on", "off"

<frameMode>         Frame Mode               String values:
                    Enable                   "on", "off"

<faxDemod>          Fax Demodulation         String values:
                    Enable                   "on", "off"

<cas>               Enable CAS transport     String values:
                    via Type 3 packets       "on", "off"

<dtmf>              Enable DTMF transport    String values:
                    via Type 3 packets       "on", "off"

<mfall>             Enable MF transport      String values:
                    via Type 3 packets       "on", "off"

<mfr1>              Enable MF (R1)           String values:
                    transport via             "on", "off"
                    Type 3 packets

<mfr2>              Enable MF (R2)           String values:
                    transport via             "on", "off"
                    Type 3 packets
Top   ToC   RFC3108 - Page 91
<PCMencoding>       PCM encoding             String values:
                                             "PCMA", "PCMU"

<fmaxFrame>         Maximum length of a      Decimal or hex
                    frame mode data unit,    equivalent of
                    forward direction        16-bit field

<bmaxFrame>         Maximum length of a      -ditto-
                    frame mode data unit,
                    backward direction

<silenceSuppEnable>  Silence suppression  String values:
                     Enable               "on", "off"

<silenceTimer>       Kick-in timer        Decimal or hex representation
                     for silence          of 16-bit field
                     suppression


<suppPref>          Preferred Silence     String values:
                    Suppression Method    "standard", "custom"

<sidUse>            SID Use               String values:
                    Method                "No SID", "Fixed Noise",
                                          "Sampled Noise"

<fxnslevel>         Fixed Noise           Decimal or hex representation
                    Level                 of a 7-bit field

<ecanEnable>        Enable Echo           String values:
                    Cancellation          "on", "off"

<ecanType>           Type of Echo         String values:
                     Cancellation         "G165", "G168"

<gcEnable>           Enable Gain          String values:
                     Control              "on", "off"

<gcLvl>              Level of inserted    Decimal or hex equivalent
                     Loss                 of 16-bit field

<aal2transport>      AAL2 transport       Values listed in Table 1
                                          that begin with the string
                                          "AAL2"

<uuiCodeRange>       UUI code range       Decimal integer 0-15
Top   ToC   RFC3108 - Page 92
<encodingName>       Encoding name        String values:
                                          "PCMG", "SIDG", "SID729",
                                          any value from column 2
                                          of Table 2

<packetLength>      Packet length         Decimal integer 0-45

<packetTime>        Packetization         Decimal integer 1-65,536
                    Interval in microsec.

<fxIncl>            Facsimile included    String values: "on", "off"

<serviceType>       Service type          String values: "v", "d", "f",
                                          "df", "all"

<q7655scc>          Contents of the       Even number of hex
                    Q.765.5 Single        digits (4-32)
                    Codec IE

<isupUsi>           ISUP User Service     Even number of hex digits
                    Information           (4-24)

<uiLayer1Prot>      User Information      Two hex digits
                    Layer 1 Protocol

<chainPointer>     Chain pointer          String values: "NEXT",
                                          "PREVIOUS", "NULL"

<rtcpPortNum>      RTCP port number for    Odd decimal in range 1,024 to
                   H.323 Annex C           65,535.
                   applications            Preferred: Odd number in
                                           the range 49,152 to 65,535

<rtcpIPaddr>      IP address for  receipt  Dotted decimal, 7-15 chars
                  of RTCP packets
Top   ToC   RFC3108 - Page 93

7. Examples of ATM session descriptions using SDP

An example of a complete AAL1 session description in SDP is: v=0 o=- A3C47F21456789F0 0 ATM NSAP 47.0091.8100.0000.0060.3e64.fd01.0060.3e64.fd01.00 s=- c=ATM NSAP 47.0091.8100.0000.0060.3e64.fd01.0060.3e64.fd01.00 t=0 0 m=audio $ AAL1/AVP 18 0 96 a=atmmap:96 X-G727-32 a=eecid:B3D58E32 An example of a complete AAL2 session description in SDP is: v=0 o=- A3C47F21456789F0 0 ATM NSAP 47.0091.8100.0000.0060.3e64.fd01.0060.3e64.fd01.00 s=- c=ATM NSAP 47.0091.8100.0000.0060.3e64.fd01.0060.3e64.fd01.00 t=0 0 m=audio $ AAL2/ITU 8 AAL2/custom 100 AAL2/ITU 1 a=eecid:B3E32 The AAL2 session descriptor below is the same as the one above except that it states an explicit preference for a voice codec, a voiceband data codec and a voiceband fax codec. Further, it defines the profile AAL2/custom 100 rather than assume that the far-end is cognizant of the elements of this profile. v=0 o=- A3C47F21456789F0 0 ATM NSAP 47.0091.8100.0000.0060.3e64.fd01.0060.3e64.fd01.00 s=- c=ATM NSAP 47.0091.8100.0000.0060.3e64.fd01.0060.3e64.fd01.00 t=0 0 m=audio $ AAL2/ITU 8 AAL2/custom 100 AAL2/ITU 1 a=eecid:B3E32 a=profileDesc:AAL2/custom 100 0-7 PCMG 40 5000 0-7 SIDG 1 5000 8-15 G726-32 40 10000 8-15 SIDG 1 5000 a=vsel:G726-32 40 10000 a=dsel:off PCMU - - a=fsel:G726-32 40 10000
Top   ToC   RFC3108 - Page 94
   An example of an SDP session descriptor for an AAL5 switched virtual
   circuit for delivering MPEG-2 video:

      v=0
      o=- A3C47F21456789F0 0 ATM NSAP
      47.0091.8100.0000.0060.3e64.fd01.0060.3e64.fd01.00
      s=-
      c=ATM NSAP 47.0091.8100.0000.0060.3e64.fd01.0060.3e64.fd01.00
      t=0 0
      m=video $ AAL5/ITU 33
      a=eecid:B3E32
      a=aalType:AAL5
      a=bearerType:SVC on
      a=atmTrfcDesc:f 0+1 7816 - - - - - off -
      a=atmTrfcDesc:b 0+1 0 - - - - - on -
      a=cpsSDUsize:f 20680
      a=aalApp:itu_h2221 - -

   An example of an SDP session descriptor for an AAL5 permanent virtual
   circuit for delivering MPEG-2 video:

      v=0
      o=- A3C47F21456789F0 0 ATM - -
      s=-
      c=ATM - -
      t=0 0
      m=video PORT-$/VPI-0/VCI-$ AAL5/ITU 33
      a=bearerType:PVC -
      a=atmTrfcDesc:f 0+1 7816 - - - - - off -
      a=atmTrfcDesc:b 0+1 0 - - - - - on -
      a=cpsSDUsize:f 20680
      a=aalApp:itu_h2221 - -

8. Security Considerations

8.1 Bearer Security

At present, standard means of encrypting ATM and AAL2 bearers are not conventionalized in the same manner as means of encrypting RTP payloads. Nor has the authentication of ATM or AAL2 bearer signaling. The SDP encryption key line (k=) defined in RFC 2327 can be used to represent the encryption key and the method of obtaining the key. In the ATM and AAL2 contexts, the term 'bearer' can include 'bearer signaling' as well as 'bearer payloads'.
Top   ToC   RFC3108 - Page 95

8.2 Security of the SDP description

The SDP session descriptions might originate in untrusted areas such as equipment owned by end-subscribers or located at end-subscriber premises. SDP relies on the security mechanisms of the encapsulating protocol or layers below the encapsulating protocol. Examples of encapsulating protocols are the Session Initiation Protocol (SIP), MGCP and Multimedia Gateway Control Protocol (MEGACO). No additional security mechanisms are needed. SIP, MGCP and MEGACO can use IPSec authentication as described in RFC 1826 [Ref. 27]. IPSec encryption can be optionally used with authentication to provide an additional, potentially more expensive level of security. IPSec security associations can be made between equipment located in untrusted areas and equipment located in trusted areas through configured shared secrets or the use of a certificate authority.

9. ATM SDP Grammar

This appendix provides an Augmented BNF (ABNF) grammar for the ATM conventions for SDP. ABNF is defined in rfc2234. This is not a complete ABNF description of SDP. Readers are referred to [1] for an ABNF description of the SDP base line protocol, and to rfc2848, rfc2543, rfc2045 and rfc2326 for application-specific conventions for SDP use. For case conventions, see section 2.4. ; Constant definitions safe = alpha-numeric / "'" / "-" / "." / "/" / ":" / "?" / DQUOTE / "#" / "$" / "&" / "*" / ";" / "=" / "@" / "[" / "]" / "^" / "_" / "`" / "{" / "|" / "}" / "+" / "~" DQUOTE = %x22 ; double quote alpha-numeric = ALPHA / DIGIT ALPHA = "a" / "b" / "c" / "d" / "e" / "f" / "g" / "h" / "i" / "j" / "k" / "l" / "m" / "n" / "o" / "p" / "q" / "r" / "s" / "t" / "u" / "v" / "w" / "x" / "y" / "z" / "A" / "B" / "C" / "D" / "E" / "F" / "G" / "H" / "I" / "J" / "K" / "L" / "M" / "N" / "O" / "P" / "Q" / "R" / "S" / "T" / "U" / "V" / "W" / "X" / "Y" / "Z" DIGIT = "0" / POS-DIGIT POS-DIGIT = "1" / "2" / "3" / "4" / "5" / "6" / "7" / "8" / "9" hex-prefix = "0" ("x" / "X") HEXDIG = DIGIT / "a" / "b" / "c" / "d" / "e" / "f" / "A" / "B" / "C" / "D" / "E" / "F" space = %d32 EOL = (CR / LF / CRLF) ; as per Megaco RFC CR = %d13 LF = %d10
Top   ToC   RFC3108 - Page 96
decimal-uchar =       DIGIT
                         / POS-DIGIT DIGIT
                         / ("1" 2*(DIGIT))
                         / ("2" ("0"/"1"/"2"/"3"/"4") DIGIT)
                         / ("2" "5" ("0"/"1"/"2"/"3"/"4"/"5"))

generic-U8  = (hex-prefix hex-U8) / decimal-uchar
generic-U12 = (hex-prefix hex-U12) / 1*4 (DIGIT)
generic-U16 = (hex-prefix hex-U16) / 1*5(DIGIT)
generic-U24 = (hex-prefix hex-U24) / 1*8(DIGIT)
generic-U32 = (hex-prefix hex-U32) / 1*10(DIGIT)
hex-U8  = 1*2(HEXDIG)
hex-U12 = 1*3(HEXDIG)
hex-U16 = 1*4(HEXDIG)
hex-U24 = 1*6(HEXDIG)
hex-U32 = 1*8(HEXDIG)
generic-U8-or-null  = generic-U8 / "-"
generic-U12-or-null = generic-U12 / "-"
generic-U16-or-null = generic-U16 / "-"
generic-U24-or-null = generic-U24 / "-"
generic-U32-or-null = generic-U32 / "-"
decimal-U8-or-null =  decimal-uchar / "-"
decimal-U12-or-null = 1*4(DIGIT) / "-"
decimal-U16-or-null = 1*5(DIGIT) / "-"
decimal-U24-or-null = 1*8 (DIGIT) / "-"
decimal-U32-or-null = 1*10(DIGIT) / "-"
on-off-or-null = "on" / "off" / "-"

; ABNF definition of SDP with ATM conventions

SDP-infoset    =  1*(announcement)announcement  =  proto-version
origin-field   session-name-field   information-field   uri-field
email-fields   phone-fields   connection-field bandwidth-fields
time-fields key-field attribute-fields media-descriptions

proto-version = ["v=" 1*4(DIGIT) EOL] ; use "v=0" for ATM SDP

origin-field = ["o=" username space sess-id space sess-version space
   net-type-addr EOL]

username = 1* safe ; for ATM use "-"

sess-id = (1*32 DIGIT) / (hex-prefix 1*32 HEXDIG)
sess-version = (1*10 DIGIT) / (hex-prefix 1*8 HEXDIG)

net-type-addr= nettype space addrtype-addr

netttype = "ATM" / "IN" / "TN" / "-" / "$"
Top   ToC   RFC3108 - Page 97
 ; Other nettype values may be defined in the future in other documents
 ; Validity of  nettype and addrtype-addr combination to be checked at
 ;      application level, not protocol syntax level

addrtype-addr = atm-addrtype-addr / ip-addrtype-addr / tn-addrtype-addr
   ; ip-addrtype-addr per rfc2327
   ; tn-addrtype-addr per rfc2848

; ATM address definition

atm-addrtype-addr =  atm-nsap-addr / atm-e164-addr / atm-alias-addr

atm-nsap-addr = ("NSAP" / "-" / "$")  space (nsap-addr / "-" / "$")
atm-e164-addr = ("E164" / "-" / "$") space (e164-addr / "-" / "$")
atm-alias-addr = ("GWID" / "ALIAS" / "-" / "$") space (alias-addr /
                  "-" / "$")

nsap-addr = 2(HEXDIG) "." 9(4(HEXDIG) ".") 2(HEXDIG)

e164-addr = 1*15 (DIGIT)
alias-addr = 1*32(alpha-numeric / "-" / "." / "_")

session-name-field = ["s=" text EOL] ; for ATM use "s=-"
text = byte-string
byte-string = 1*(byte-string-char) ; definition per rfc2327
byte-string-char = %x01-09/ %x0B/ %x0C/ %x0E-FF ; all ASCII except
                   NUL, CR & LF
; Definitions of information-field, uri-field, email-fields,
; phone-fields per rfc2327.  These fields are omitted in
; ATM SDP descriptions.  If received, they are ignored in the ATM
; context

connection-field = ["c=" c-net-type-addr]

         ; connection-field required, not optional, in ATM

c-net-type-addr = nettype space c-addrtype-addr
c-addrtype-addr = atm-addrtype-addr / c-ip-addrtype-addr /
                  tn-addrtype-addr

   ; atm-addrtype-addr defined above

   ; c-ip-addrtype-addr per rfc2327
   ; difference in address usage between 'o' and 'c' lines per rfc2327

   ; tn-addrtype-addr per rfc2848

bandwidth-fields = *("b=" bwtype ":" bandwidth EOL)
Top   ToC   RFC3108 - Page 98
bwtype = 1*(alpha-numeric)
bandwidth = 1*(DIGIT)

time-fields = *( "t=" start-time space stop-time
              *(EOL repeat-fields) EOL)
              [zone-adjustments EOL]
start-time = time / "0"
stop-time = time / "0" ; always "0" in ATM
time = POS-DIGIT 9*(DIGIT) ; same as rfc2327
 ; repeat-fields and zone-adjustments per rfc2327, not used in ATM

 ; Definition of optional key-field per rfc2327
 ;

attribute-fields = *("a=" attribute EOL)

 ; SDP descriptors for ATM do not have session-level media attribute
 ; lines.  If these are provided, they should be ignored.

media-descriptions = *(media-description)
media-description  = media-field information-field *(connection-field)
                     bandwidth-fields key-field attribute-fields

; Definitions of information-field per RFC 2327.  These fields are
; omitted in ATM SDP descriptions.  If received, they are ignored in
; the ATM context
;
; In ATM, the connection-field is used in media-description to indicate
; the IP address associated with the RTCP control protocol in H.323.C
; applications.  In this case,  the connection field is per the RFC 2327
; definition for IP v4-based connections.  Otherwise, it is not used in
; media-description.  If received as part of  media-description,
; it is ignored.
;
; Definition of optional bandwidth-fields as above.
: Definition of optional key-field as in RFC 2327

media-field = rfc2327-media-field / rfc2848-media-field /
              atm-media-field
    ; rfc2327-media-field and rfc2848-media-field defined in those rfc's
atm-media-field = "m=" media space vcId space transport-fmts EOL
   ; superset of rfc2327 definition

media = "audio" / "video" / "data" / "application" / "control" /
        1*(alpha-numeric)

vcId = "$" / "-" / ex-vcci / (ex-vcci "/" ex-cid) /
     (atm-type-addr-m  "/" ex-vcci) /
Top   ToC   RFC3108 - Page 99
     (atm-type-addr-m "/" ex-vcci "/" ex-cid) /
     (ex-bcg "/" ex-vcci) / (ex-bcg "/" ex-vcci "/" ex-cid)
     (ex-portid "/" ex-vpi "/" ex-vci) /
     (ex-portid "/" ex-vpi "/" ex-vci "/" ex-cid) /
     (ex-bcg "/" ex-vpi "/" ex-vci) /
     (ex-bcg "/" ex-vpi "/" ex-vci "/" ex-cid) /
     (ex-vpci "/" ex-vci) /
     (ex-vpci "/" ex-vci "/" ex-cid) /
     (atm-type-addr-m  "/" ex-vpci "/" ex-vci) /
     (atm-type-addr-m  "/" ex-vpci "/" ex-vci "/" ex-cid)

atm-type-addr-m = atm-nsap-addr-m / atm-e164-addr-m / atm-alias-addr-m
atm-nsap-addr-m =  ["NSAP-"] (nsap-addr / "$")
atm-e164-addr-m =  ["E164-"] (e164-addr / "$")
atm-alias-addr-m = ["GWID-" / "ALIAS-"] (alias-addr / "$")
 ; The -m at the end indicates use in the media field
 ; Wildcarding rules different from ATM address on 'o' and 'c' lines

ex-vcci    = "VCCI-"  vcci
ex-cid     = "CID-"   cid
ex-bcg     = "BCG-"   bcg
ex-portid  = "PORT-"  portid
ex-vpi     = "VPI-"   vpi
ex-vci     = "VCI-"   vci
ex-vpci    = "VPCI-"  vpci

vcci   = generic-U16
cid    = generic-U8
bcg    = generic-U8
portid = 1*32 (HEXDIG)
vpi    = generic-U12
vci    = generic-U16
vpci   = generic-U16


transport-fmts = generic-transport-fmts / known-transport-fmts / "- -"
generic-transport-fmts = generic-transport 1*(space fmt)
generic-transport = 1*(alpha-numeric / "/")
fmt = 1*(alpha-numeric)

known-transport-fmts = aal1-transport space aal1-fmt-list /
                       aal2-transport space aal2-fmt-list
                       *(space aal2-transport space aal2-fmt-list) /
                       aal5-transport space aal5-fmt-list /
                       rtp-transport space rtp-fmt-list /
                       tn-proto space tn-fmt-list /
                       h323c-proto "-"
h323c-proto = "H323c"
Top   ToC   RFC3108 - Page 100
    ; h323c-proto used for RTCP control ports in H.323 annex C
    ; applications.  tn-proto and tn-fmt-list per rfc2848

aal1-transport = "AAL1" "/" aal1-transport-list
aal1-transport-list = "ATMF" / "ITU" / "custom" / "IEEE:" oui /
                      corporate-name
corporate-name = 1*(safe)
aal2-transport = "AAL2" "/" aal2-transport-list
aal2-transport-list = aal1-transport-list
aal5-transport = "AAL5" "/" aal5-transport-list
aal5-transport-list = aal1-transport-list
rtp-transport = "RTP" "/" rtp-transport-list
rtp-transport-list = "AVP"

aal1-fmt-list = (payload-type *(space payload-type)) / "-"
payload-type = decimal-uchar
aal5-fmt-list = aal1-fmt-list
rtp-fmt-list = aal1-fmt-list
aal2-fmt-list = (profile *(space profile)) / "-"
profile = decimal-uchar
attribute-fields = *("a=" attribute EOL)
attribute = known-attribute / (generic-att-field ":" att-value) /
            generic-att-field
generic-att-field = 1*(alpha-numeric)
att-value = byte-string
known-attribute = atm-attribute / PINT-attribute / rfc2327-attribute
         ; PINT-attribute as defined in rfc2848
         ; rfc2327 attribute as defined in that rfc

atm-attribute =
      "eecid" ":" eecid /
      "aalType" ":" aalType /
      "capability" ":" (asc / atc) space subtype /
      "qosclass" ":" qosclass /
      "bcob" ":" bcob space eetim /
      "stc" ":" stc /
      "upcc" ":" upcc /
      "atmQOSparms" ":" directionFlag space cdvType
                      space acdv space ccdv space eetd space cmtd
                      space aclr /
      "atmTrfcDesc" ":" directionFlag space clpLvl
                      space pcr space scr space mbs space cdvt space
                      mcr space mfs space fd space te /
      "abrParms" ":" directionFlag  space nrm space trm space cdf
                    space adtf /
      "abrSetup" ":" ficr space bicr space ftbe space btbe space
             crmrtt space frif space brif space frdf space brdf /
      "bearertype" ":" bearerType space localInitiation  /
Top   ToC   RFC3108 - Page 101
      "lij" ":" sci space lsn /
      "anycast" ":" atmGroupAddress space cdStd space
                 conScpTyp space conScpSel /
      "cache" ":" cacheEnable space cacheTimer /
      "bearerSigIE" ":" bearerSigIEType space
               bearerSigIELng space bearerSigIEVal /
      "aalApp" ":" appClass space oui space appId /
      "cbrRate" ":" cbrRate /
      "sbc" ":" sbc /
      "clkrec" ":" clkrec /
      "fec" ":" fecEnable /
      "prtfl" ":" partialFill /
      "structure" ":" structureEnable space blksz /
      "cpsSDUsize" ":" directionFlag space cpcs /
      "aal2CPS" ":" cidLowerLimit space cidUpperLimit space
               timerCU space simplifiedCPS /
      "aal2CPSSDUrate" ":" fSDUrate space bSDUrate /
      "aal2sscs3661unassured" ":" ted space rastimer space fsssar
                space bsssar /
      "aal2sscs3661assured" ":" rastimer space fsssar space bsssar
           space fsscopsdu space bsscopsdu space fsscopuu
           space bsscopuu  /
      "aal2sscs3662" ":" sap space circuitMode space frameMode
           space faxDemod space cas space dtmf space mfall space mfr1
           space mfr2 space PCMencoding space fmaxFrame
           space bmaxFrame /
      "aal5sscop" ":" fsscopsdu space bsscopsdu space fsscopuu
             space bsscopuu  /
      "atmmap" ":" payload-type space encoding-name /
      "silenceSupp" ":" silenceSuppEnable space silenceTimer
               space suppPref space sidUse space fxnslevel /
      "ecan" ":" directionFlag space ecanEnable space ecanType /
      "gc" ":" directionFlag space gcEnable space gcLvl /
      "profileDesc" ":" aal2-transport space profile space
         1*(profile-row) /
      "vsel" ":" 1*(encoding-name space packet-length space
                                  packet-time space) /
      "dsel" ":" fxIncl space
                 1*(encoding-name space packet-length space
                                  packet-time space) /
      "fsel" ":" 1*(encoding-name space packet-length space
                                  packet-time space) /
      "onewaySel" ":" serviceType space directionFlag space
                 1*(encoding-name space packet-length space
                                  packet-time space) /

      "codecconfig" ":" q7655scc /
      "isup_usi" ":" isupUsi /
Top   ToC   RFC3108 - Page 102
      "uiLayer1_Prot" ":" uiLayer1Prot /
      "chain" ":" chainPointer

eecid =  8 (HEXDIG)
aalType = "AAL1" / "AAL2" / "AAL3/4" / "AAL5" / "USER_DEFINED_AAL"
asc = "CBR" / "nrt-VBR" / "rt-VBR" / "UBR" / "ABR" / "GFR"
atc = "DBR" / "SBR" / "ABT/IT" / "ABT/DT" / "ABR"
subtype = decimal-U8-or-null
qosclass = decimal-U8-or-null
bcob = generic-U8
eetim = on-off-or-null
stc = decimal-uchar
upcc = decimal-uchar
directionFlag = "f" / "b" / "fb"
cdvType = "PP" / "2P" / "-"
acdv = decimal-U32-or-null
ccdv = decimal-U32-or-null
eetd = decimal-U16-or-null
cmtd = decimal-U16-or-null
aclr = decimal-U8-or-null
clpLvl = "0" / "0+1" / "-"
pcr = decimal-U24-or-null
scr = decimal-U24-or-null
mbs = decimal-U16-or-null
cdvt = decimal-U24-or-null
mcr = decimal-U24-or-null
mfs = decimal-U16-or-null
fd = on-off-or-null
te = on-off-or-null
nrm = generic-U8-or-null
trm = generic-U8-or-null
cdf = generic-U8-or-null
adtf = generic-U16-or-null
ficr = decimal-U24-or-null
bicr = decimal-U24-or-null
ftbe = decimal-U24-or-null
btbe = decimal-U24-or-null
crmrtt = decimal-U24-or-null
frif = 1*2 (DIGIT)
brif = 1*2 (DIGIT)
frdf = 1*2 (DIGIT)
brdf = 1*2 (DIGIT)
bearerType =  "PVC" / "SVC" / "CID"
localInitiation = on-off-or-null
sci = generic-U8-or-null
lsn = generic-U32-or-null
atmGroupAddress = atm-type-addr
cdStd = generic-U8-or-null
Top   ToC   RFC3108 - Page 103
conScpTyp = generic-U8-or-null
conScpSel = generic-U8-or-null
cacheEnable = on-off-or-null
cacheTimer = generic-U32-or-null
bearerSigIEType = 2 * (HEXDIG)
bearerSigIELng = 1*4 (HEXDIG)
bearerSigIEVal = 2*512 (HEXDIG)
appClass =  "-" /
          "itu_h323c" / "af83" / "AAL5_SSCOP" / "itu_i3661_unassured" /
          "itu_ i3661_assured"/ "itu_i3662"/ "itu_i3651" /
          "itu_i3652" / "itu_i3653" / "itu_i3654" / "FRF11" / "FRF5" /
          "FRF8" / "itu_h2221"
oui = "-" / 1*6 (HEXDIG)
appId = "-" / 1*8 (HEXDIG)
cbrRate = 2 (HEXDIG)
sbc = generic-U8
clkrec = "NULL" / "SRTS" / "ADAPTIVE"
fecEnable = "NULL" / "LOSS_SENSITIVE"  / "DELAY_SENSITIVE"
partialFill = generic-U8
structureEnable = on-off-or-null
blksz = generic-U16-or-null
cpcs = generic-U16
cidLowerLimit = generic-U8-or-null
cidUpperLimit = generic-U8-or-null
timerCU = decimal-U32-or-null
simplifiedCPS = on-off-or-null
fSDUrate = decimal-U24-or-null
bSDUrate = decimal-U24-or-null
ted = on-off-or-null
rastimer = decimal-U32-or-null
fsssar = generic-U24-or-null
bsssar = generic-U24-or-null
fsscopsdu = generic-U16-or-null
bsscopsdu = generic-U16-or-null
fsscopuu = generic-U16-or-null
bsscopuu = generic-U16-or-null
sap = "AUDIO" / "MULTIRATE" / "-"
circuitMode = on-off-or-null
frameMode = on-off-or-null
faxDemod = on-off-or-null
cas = on-off-or-null
dtmf = on-off-or-null
mfall = on-off-or-null
mfr1 = on-off-or-null
mfr2 = on-off-or-null
PCMencoding = "PCMA" / "PCMU" / "-"
fmaxframe = generic-U16-or-null
bmaxframe = generic-U16-or-null
Top   ToC   RFC3108 - Page 104
silenceSuppEnable = on-off-or-null
silenceTimer = generic-U16-or-null
suppPref = "standard" / "custom" / "-"
sidUse = "No SID" / "Fixed Noise" / "Sampled Noise" / "-"
fxnslevel = generic-U8-or-null
ecanEnable = on-off-or-null
ecanType = "G165" / "G168" / "-"
gcEnable = on-off-or-null
gcLvl = generic-U16-or-null

profile-row  = uuiCodeRange space encoding-name space packet-length
                   space packet-time space
uuiCodeRange = decimal-uchar "-" decimal-uchar / "-"
encoding-name = "-" /
                "PCMG" / "SIDG" / "SID729" /
                "PCMU" / "G726-32" / "G723" / "PCMA" / "G722" / "G728" /
                "G729" / "X-G729a" / "X-G729b" / "X-G729ab" /
                "X-G726-16" / "X-G726-24" / "X-G726-40" / "X-G7231-H" /
                "X-G7231-L" / "X-G7231a-H" / "X-G7231a-L" /
                "X-G727-16" / "X-G727-24" / "X-G727-32" /
                "X-CCD" / "X-CCD-CAS" / "GSM" / "GSM-HR" / "GSM-EFR" /
                "GSM-EHR" / "X-FXDMOD-3" / "1016" / "DVI4" / "L16" /
                "LPC" / "MPA" / "QCELP" / "H263" / "H263-1998" /
                "JPEG" / "H261" / "MPV" / "MP2T" / "nv" / "RED" /
                "CelB" / "L8" / "VDVI" / "MP1S" / "MP2P" / "BT656" /
                "FR-AMR" / "HR-AMR" / "UMTS-AMR" / "AMR"
packet-length = decimal-U8-or-null
packet-time = decimal-U16-or-null
fxIncl = on-off-or-null
serviceType = "v" / "d" / "f" / "df" / "all"
q7655scc = 4*32 (HEXDIG)
isupUsi = 4*24 (HEXDIG)
uiLayer1Prot = 2 (HEXDIG)

chainPointer = "NEXT" / "PREVIOUS" / "NULL"

References

[1] Handley, M. and V. Jacobson, "SDP: Session Description Protocol", RFC 2327, April 1998. [2] Schulzrinne, H., Casner, S., Frederick, R. and V. Jacobson, "RTP: A Transport Protocol for Real-Time Applications", RFC 1889, January 1996. RFC 1889 will be obsoleted, in a substantially backwards compatible manner, by a work in progress that will become an RFC.
Top   ToC   RFC3108 - Page 105
   [3]  Schulzrinne, H., "RTP Profile for Audio and Video Conferences
        with Minimal Control", RFC 1890, January 1996.

        RFC 1890 will be obsoleted, in a fully backwards compatible
        manner, by a work in progress that will become an RFC.

   [4]  ATMF UNI 3.1 Specification,  af-uni-0010.002. Of special
        interest for this document is  Section 5.4.5.5,  ATM Adaptation
        Layer Parameters.

   [5]  ATMF UNI 4.0 Signaling Specification, af-sig-0061.000.

   [6]  ATMF Traffic Management Specification, Version 4.1, af-tm-
        0121.000.

   [7]  ATMF Circuit Emulation Service (CES) Interoperability
        Specification, version 2.0, af-vtoa-0078.000, Jan. 97.

   [8]  ATMF Voice and Telephony over ATM - ATM Trunking using AAL1 for
        Narrowband Services, version 1.0, af-vtoa-0089.000, July 1997.

   [9]  ATMF Specifications of (DBCES) Dynamic Bandwidth Utilization -
        in 64kbps Timeslot Trunking over ATM  - using CES, af-vtoa-
        0085.000, July 1997.

   [10] ITU-T I.363.1, B-ISDN ATM Adaptation Layer Specification: Type 1
        AAL, August 1996.

   [11] ITU-T I.363.2, B-ISDN ATM Adaptation Layer Specification: Type 2
        AAL, Sept. 1997.

   [12] ITU-T I.366.1, Segmentation and Reassembly Service Specific
        Convergence Sublayer  for AAL Type 2, June 1998.

   [13] ITU-T I.366.2, AAL Type 2 Reassembly Service Specific
        Convergence Sublayer  for Trunking, Feb. 99.

   [14] Petrack, S., "RTP payloads for Telephone Signal Events", Work in
        Progress.

   [15] ITU-T Q.2931, B-ISDN Application Protocol for Access Signaling.

   [16] Amendment 1, 2, 3 and 4 to ITU-T Q.2931, B-ISDN Application
        Protocol for Access Signaling.

   [17] Handley, M., Perkins C. and E. Whelan, "Session Announcement
        Protocol", RFC 2974, October 2000.
Top   ToC   RFC3108 - Page 106
   [18] Handley, M., Schulzrinne, H., Schooler, E. and J. Rosenberg,
        "Session Initiation Protocol (SIP)", RFC 2543, March 1999.

   [19] Almquist, P., "Type of Service in the Internet Protocol Suite",
        July 1992.

   [20] Nichols, K., Blake, S., Baker, F. and D. Black, "Definition of
        the Differentiated Services Field (DS Field) in the IPv4 and
        IPv6 Headers", December 1998.

   [21] ITU-T I.363.5, B-ISDN ATM Adaptation Layer Specification: Type 5
        AAL, Aug. 1996.

   [22] ATMF PNNI 1.0, af-pnni-0055.000, March 1996.

   [23] Schulzrinne, H., Casner, S., Frederick, R. and V. Jacobson,
        "RTP: A Transport Protocol for Real-Time Applications", Work in
        Progress.

   [24] Schulzrinne, H. and S. Casner, "RTP Profile for Audio and Video
        Conferences with Minimal Control", Work in Progress.

   [25] Arango, M., Dugan, A., Elliott, I., Huitema, C. and S. Pickett,
        "Media Gateway Control Protocol (MGCP)", RFC 2705, October 1999.

   [26] Cuervo, F., Greene, N., Rayhan, A., Huitema, C., Rosen, B. and
        J.  Segers, "Megaco Protocol Version 1.0", RFC 3015, November
        2000.

   [27] Atkinson, R., "IP Authentication Header", RFC 1826, August 1995.

   [28] ITU I.371, Traffic Control and Congestion Control in the BISDN.

   [29] ITU E.191, BISDN Numbering and Addressing.

   [30] ATM Forum Addressing: Reference Guide, af-ra-0106.000.

   [31] http://www.iana.org/assignments/rtp-parameters for a list of
        codecs with static payload types.

   [32] ITU Q.2941-2, Digital Subscriber Signalling System No. 2 (DSS
        2): Generic identifier transport extensions.

   [33] ITU Q.2961, Digital subscriber signalling system no.2 (DSS 2) -
        additional traffic parameters. Also, Amendment 2 to Q.2961.

   [34] ITU Q. 2965.1, Digital subscriber signalling system no.2 (DSS 2)
        - Support of Quality of Service classes.
Top   ToC   RFC3108 - Page 107
   [35] ITU Q. 2965.2, Digital subscriber signalling system no.2 (DSS 2)
        - Signalling of individual Quality of Service parameters.

   [36] ITU Q.1901, Bearer Independent Call Control Protocol.

   [37] ITU Q.2630.1, AAL type 2 signaling protocol - capability set 1.

   [38] ITU I.363.5, B-ISDN ATM Adaptation Layer specification: Type 5
        AAL.

   [39] I.365.1,Frame relaying service specific convergence sublayer
        (FR-SSCS).

   [40] I.365.2, B-ISDN ATM adaptation layer sublayers: service specific
        coordination function to provide the connection oriented network
        service.

   [41] I.365.3, B-ISDN ATM adaptation layer sublayers: service specific
        coordination function to provide the connection-oriented
        transport service.

   [42] I.365.4, B-ISDN ATM adaptation layer sublayers: Service specific
        convergence sublayer for HDLC applications.

   [43] Q.2110, B-ISDN ATM adaptation layer - service specific
        connection oriented  protocol (SSCOP).

   [44] af-vtoa-0113.000, ATM trunking using AAL2 for narrowband
        services.

   [45] H.323-2, Packet-based multimedia communications systems.

   [46] af-vtoa-0083.000, Voice and Telephony Over ATM to the Desktop.

   [47] I.356, BISDN ATM layer cell transfer performance.

   [48] ITU Q.2957, Digital Subscriber Signaling System No. 2, User to
        user signaling.

   [49] Mills, D., "Network Time Protocol (Version 3) Specification,
        Implementation and Analysis", RFC 1305, March 1992.

   [50] TIA/EIA/IS-J-STD-025-A, Lawfully Authorized Electronic
        Surveillance, May 2000.

   [51] ITU-T H.222.1, Multimedia multiplex and synchronization for
        audiovisual communication in ATM environments.
Top   ToC   RFC3108 - Page 108
   [52] af-vmoa-0145.000, Voice and Multimedia over ATM, Loop Emulation
        Service using AAL2.

   [53] FRF.5, Frame Relay/ATM PVC Network Interworking Implementation
        Agreement.

   [54] FRF.8.1, Frame Relay/ATM PVC Service Interworking Implementation
        Agreement.

   [55] FRF.11, Voice over Frame Relay Implementation Agreement.

   [56] Crocker, D. and P. Overell, "Augmented BNF for Syntax
        Specifications: ABNF", RFC 2234, November 1997.

   [57] ITU Q.765.5, Application Transport Mechanism - Bearer
        Independent Call Control.

   [58] http://www.3gpp.org/ftp/Specs for specifications related to
        3GPP, including AMR codecs.

   [59] ITU Q.931, Digital Subscriber Signaling System No. 1: Network
        Layer.

   [60] ITU Q.763, SS7 - ISUP formats and codes.

   [61] http://www.atmforum.com/atmforum/specs/specs.html, ATM Forum,
        Well-known addresses and assigned codes.

   [62] Bradner, S., "Keywords for use in RFCs to indicate requirement
        levels", BCP 14, RFC 2119, March 1997.
Top   ToC   RFC3108 - Page 109

Acknowledgements

The authors wish to thank several colleagues at Cisco and in the industry who have contributed towards the development of these SDP conventions, and who have reviewed, implemented and tested these constructs. Valuable technical ideas that have been incorporated into this internet document have been provided by Hisham Abdelhamid, Flemming Andreasen, David Auerbach, Robert Biskner, Bruce Buffam, Steve Casner, Alex Clemm, Bill Foster, Snehal Karia, Raghu Thirumalai Rajan, Joe Stone, Bruce Thompson, Dan Wing and Ken Young of Cisco, Michael Brown, Rade Gvozdanovic, Graeme Gibbs, Tom-PT Taylor, Mark Watson and Sophia Scoggins of Nortel Networks, Brian Rosen, Tim Dwight and Michael Mackey of Marconi, Ed Guy and Petros Mouchtaris of Telcordia, Christian Groves of Ericsson, Charles Eckel of Vovida Networks, Tom Jepsen, Dal Chohan, Sagar Gordhan and Chris Gallon of Fujitsu, Mahamood Hussain of Hughes Software Systems and Sean Sheedy of nCUBE Corporation, Narendra Tulpule of Intel, Albrecht Schwarz of Alcatel, and Jonathan Rosenberg of Dynamicsoft. The authors also wish to thank the ISC device control group, and the MMUSIC and MEGACO subgroups of the IETF, especially Bill Foster, Joerg Ott, Sean Sheedy and Brian Rosen for their help in the preparation of this document. Finally, thanks are due to Narendra Tulpule of Intel whose ABNF grammar was adapted for this document.

Authors' Addresses

Rajesh Kumar Cisco Systems, Inc. M/S SJC01/3 170 West Tasman Drive San Jose, CA 95134-1706 Phone: 1-800-250-4800 EMail: rkumar@cisco.com Mohamed Mostafa Cisco Systems, Inc. M/S SJC01/3 170 West Tasman Drive San Jose, CA 95134-1706 Phone: 1-800-250-4800 EMail: mmostafa@cisco.com
Top   ToC   RFC3108 - Page 110
Full Copyright Statement

   Copyright (C) The Internet Society (2001).  All Rights Reserved.

   This document and translations of it may be copied and furnished to
   others, and derivative works that comment on or otherwise explain it
   or assist in its implementation may be prepared, copied, published
   and distributed, in whole or in part, without restriction of any
   kind, provided that the above copyright notice and this paragraph are
   included on all such copies and derivative works.  However, this
   document itself may not be modified in any way, such as by removing
   the copyright notice or references to the Internet Society or other
   Internet organizations, except as needed for the purpose of
   developing Internet standards in which case the procedures for
   copyrights defined in the Internet Standards process must be
   followed, or as required to translate it into languages other than
   English.

   The limited permissions granted above are perpetual and will not be
   revoked by the Internet Society or its successors or assigns.

   This document and the information contained herein is provided on an
   "AS IS" basis and THE INTERNET SOCIETY AND THE INTERNET ENGINEERING
   TASK FORCE DISCLAIMS ALL WARRANTIES, EXPRESS OR IMPLIED, INCLUDING
   BUT NOT LIMITED TO ANY WARRANTY THAT THE USE OF THE INFORMATION
   HEREIN WILL NOT INFRINGE ANY RIGHTS OR ANY IMPLIED WARRANTIES OF
   MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE.

Acknowledgement

   Funding for the RFC Editor function is currently provided by the
   Internet Society.