SIP ↠ Examples Grammars Presence ⇾

SIP SIP‑URI SIP Headers SIP P‑Headers SDP Generic URI ABNF Notation

SIP/SIPS userinfo hostport uri‑parameters headers absoluteURI tel‑URI

ABNF for telephone-uri

RFC 3966 – Section 3 — IANA (RFC 5341)

telephone-uri =

"tel:" telephone‑subscriber

; examples:
; tel:+1-201-555-0123
; tel:7042;phone-context=example.com
; tel:863-1234;phone-context=+1-914-555

telephone-subscriber =

global‑number / local‑number

global-number =

global‑number‑digits *par

global-number-digits =

"+" *phonedigit DIGIT *phonedigit

phonedigit =

DIGIT / [ visual‑separator ]

local-number =

local-number-digits *par context *par

local-number-digits =

*phonedigit-hex ( HEXDIG / "*" / "#" ) *phonedigit‑hex

phonedigit-hex =

HEXDIG / "*" / "#" / [ visual‑separator ]

context =

";phone-context=" descriptor

descriptor =

domainname / global‑number‑digits

domainname =

*( domainlabel "." ) toplabel [ "." ]

domainlabel =

alphanum / alphanum *( alphanum / "-" ) alphanum

toplabel =

ALPHA / ALPHA *( alphanum / "-" ) alphanum

par =

parameter / extension / isdn‑subaddress / ; see RFC 3966
rn / cic / npdi / ; see RFC 4694 – Section 4
isub‑encoding / ; see RFC 4715 – Section 5
enum‑dip‑indicator / ; see RFC 4759 – Section 3
trunk‑group / trunk‑context / ; see RFC 4904 – Section 5
premrate / ; see 3GPP TS 24.229 – Section 7.2A.17
verstat ; see 3GPP TS 24.229 – Section 7.2A.20

parameter =

";" pname [ "=" pvalue ]

pname =

1*( alphanum / "-" )

pvalue =

1*paramchar

paramchar =

param-unreserved / unreserved / pct‑encoded

param-unreserved =

"[" / "]" / "/" / ":" / "&" / "+" / "$"

extension =

";ext=" 1*phonedigit

isdn-subaddress =

";isub=" 1*uric

uric =

reserved / unreserved / pct‑encoded

rn =

";rn=" ( global‑rn / local‑rn )

cic =

";cic=" ( global-cic / local‑cic )

npdi =

";npdi"

global-rn =

global-hex-digits

local-rn =

1*hex-phonedigit rn‑context

rn-context =

";rn-context=" rn‑descriptor

rn-descriptor =

domainname / global-hex-digits

global-hex-digits =

"+" 1*3( DIGIT ) *hex‑phonedigit

hex-phonedigit =

HEXDIG / visual‑separator

global-cic =

global‑hex‑digits

local-cic =

1*hex-phonedigit cic‑context

cic-context =

";cic-context=" rn‑descriptor

isub-encoding =

isub-encoding-tag "=" isub‑encoding‑value

isub-encoding-tag =

"isub-encoding"

isub-encoding-value =

"nsap-ia5" / "nsap-bcd" / "nsap" / token

enum-dip-indicator =

";enumdi"

trunk-group =

";tgrp=" trunk‑group‑label

trunk-context =

";trunk-context=" descriptor

trunk-group-label =

1*( unreserved / escaped / trunk‑group‑unreserved )

trunk-group-unreserved =

"/" / "&" / "+" / "$"

pct-encoded =

"%" HEXDIG HEXDIG

premrate =

premrate‑tag "=" premrate‑value

premrate-tag =

"premium-rate"

premrate-value =

"information" / "entertainment"

verstat =

verstat‑tag "=" verstat‑value

verstat-tag =

"verstat"

verstat-value =

"TN‑Validation‑Passed" / "TN‑Validation‑Failed" / "No‑TN‑Validation" / other‑value

other-value =

token

visual-separator =

"-" / "." / "(" / ")"