Tech-invite  3GPPspecs  Glossaries  IETF  RFCs  Groups  SIP  ABNFs   Ti+  SearchTech-invite World Map Symbol
SIP   SIP URIs   SIP Headers   SIP P‑Headers   SDP   HTTP   Generic URI   IRI   IMF   RTSP   ABNF Notation

ABNF for IMF – Internet Message Format – RFC 5322

Message Format   Fields   Address   Date‑Time   Lexical Tokens

IMF — Address

RFC 5322 – Section 3.4 – Section 4.4
Section A.1 – Section A.6.1

address   =
mailbox  /  group
mailbox   =
name‑addr  /  addr‑spec
name-addr   =
[ display-name ]   angle-addr
angle-addr   =
[ CFWS ]   "<"   addr‑spec   ">"   [ CFWS ]  /  obs-angle-addr
group   =
display-name   ":"   [ group-list ]   ";"   [ CFWS ]
display-name   =
phrase
mailbox-list   =
(  mailbox   *( ","   mailbox )  )  /  obs-mbox-list
address-list   =
(  address   *( ","   address )  )  /  obs-addr-list
group-list   =
mailbox-list  /  CFWS  /  obs-group-list
obs-angle-addr   =
[ CFWS ]   "<"   obs-route   addr‑spec   ">"   [ CFWS ]
obs-route   =
obs-domain-list   ":"
obs-domain-list   =
*( CFWS  /  "," )   "@"   domain   *( ","   [ CFWS ]   [ "@"   domain ] )
obs-mbox-list   =
*( [ CFWS ]   "," )   mailbox   *( ","   [ mailbox  /  CFWS ] )
obs-addr-list   =
*( [ CFWS ]   "," )   address   *( ","   [ address  /  CFWS ] )
obs-group-list   =
1*( [ CFWS ]   "," )   [ CFWS ]
addr-spec   =
local-part   "@"   domain
local-part   =
dot-atom  /  quoted‑string  /  obs-local-part
domain   =
dot-atom  /  domain-literal  /  obs-domain
domain-literal   =
[ CFWS ]   "["   *( [ FWS ]   dtext )   [ FWS ]   "]"   [ CFWS ]
dtext   =
%d33-90  /  %d94-126
;  Printable US-ASCII characters not including "[", "]", or "\"
/  obs-dtext
obs-local-part   =
word   *( "."   word )
obs-domain   =
atom   *( "."   atom )
obs-dtext   =
obs-NO-WS-CTL  /  quoted‑pair