tech-invite   World Map     

IETF     RFCs     Groups     SIP     ABNFs    |    3GPP     Specs     Gloss.     Arch.     IMS     UICC    |    Misc.    |    search     info

SDP attributes defined in RFC 4568

12  of  59

 

Here

 

Top

 

Up

 

Prev

 

Next

 

Security Descriptions for Media Streams
crypto

RFC 4568 – Section 9

a=crypto:   (media-level)


attribute-fields   =/
crypto-attr   =
"a=crypto:"   tag   1*WSP   crypto-suite   1*WSP   key-params   *( 1*WSP   session-param )   CRLF

tag   =
1*9DIGIT

crypto-suite   =
1*( ALPHA  /  DIGIT  /  "_" )

key-params   =
key-param   *( ";"   key-param )

key-param   =
key-method   ":"   key-info

key-method   =
"inline"  /  key-method-ext

key-method-ext   =
1*( ALPHA  /  DIGIT  /  "_" )
;  see  Registration with IANA

key-info   =
1*( %x21-3A  /  %x3C-7E )
;  visible (printing) chars except semi-colon

session-param   =
1*( VCHAR )
;  visible (printing) chars




crypto-suite   =
key-method   =
key-info   =
session-param   =
srtp-crypto-suite   =
"AES_CM_128_HMAC_SHA1_32"  / ;  see RFC 4568
"F8_128_HMAC_SHA1_32"  / ;  see RFC 4568
"AES_CM_128_HMAC_SHA1_80"  / ;  see RFC 4568
"SEED_CTR_128_HMAC_SHA1_80"  / ;  see RFC 5669 – Section 7
"SEED_128_CCM_80"  / ;  see RFC 5669
"SEED_128_GCM_96"  / ;  see RFC 5669
"AES_192_CM_HMAC_SHA1_80"  / ;  see RFC 6188 – Section 5
"AES_192_CM_HMAC_SHA1_32"  / ;  see RFC 6188
"AES_256_CM_HMAC_SHA1_80"  / ;  see RFC 6188
"AES_256_CM_HMAC_SHA1_32"  / ;  see RFC 6188
srtp-crypto-suite-ext

; See:  Registration with IANA


srtp-key-method   =
"inline"

; See:  Registration with IANA


srtp-key-info   =
key-salt   [ "|"   lifetime ]   [ "|"   mki ]

key-salt   =
1*( base64 )
;  binary key and salt values concatenated together, and then
; base64 encoded [RFC 4648 – Section 4]

lifetime   =
[ "2^" ]   1*( DIGIT )

mki   =
mki-value   ":"   mki-length

mki-value   =
1*DIGIT

mki-length   =
1*3DIGIT

srtp-session-param   =
kdr  /
"UNENCRYPTED_SRTP"  /
"UNENCRYPTED_SRTCP"  /
"UNAUTHENTICATED_SRTP"  /
fec-order  /
fec-key  /
wsh  /
srtp-session-extension

; See:  Registration with IANA


kdr   =
"KDR="   1*2( DIGIT )
;  range 0..24, power of two

fec-order   =
"FEC_ORDER="   fec-type

fec-type   =
"FEC_SRTP="  /  "SRTP_FEC="

fec-key   =
"FEC_KEY="   key-params

wsh   =
"WSH="   2*DIGIT
;  minimum value is 64

base64   =
ALPHA  /  DIGIT  /  "+"  /  "/"  /  "="

srtp-crypto-suite-ext   =
1*( ALPHA  /  DIGIT  /  "_" )

srtp-session-extension   =
[ "-" ]   1*( VCHAR )
;  first character must not be dash ("-")