a portal for promoting standardization knowledge

 
  IETF map Home
# SIP RFC3261's Example  
# SIP Protocol Structure
# SIP Dialogs & Routing
# SIP Service Examples
 01.Call Hold
 02.Consultation Hold
 03.Music On Hold
 04.Transfer: Unattended
 05.Transfer: Attended
 06.Transfer: Instant Messaging
 07.Call Forwarding Unconditional
 08.Call Forwarding Busy
 09.Call Forwarding No Answer
 10.3-Way Conf: 3rd Party Added
 11.3-Way Conf: 3rd Party Joins
 12.Find-Me
 13.Incoming Call Screening
 14.Outgoing Call Screening
 15.Call Park
 16.Call Pickup
 17.Automatic Redial
 18.Click to Dial
# ABNF Grammars
  - SIP Messages & URIs
  - SIP Headers
  - SIP Private Headers
  - SDP
  - URI Generic Syntax
  - ABNF Notation & Rules
# Cryptography Basics

ABNF Grammars
SIP Private Headers

# P-Access-Network-Info # P-Answer-State # P-Asserted-Identity # P-Asserted-Service # P-Associated-URI # P-Called-Party-ID
# P-Charging-Function-Addresses # P-Charging-Vector # P-DCS-Billing-Info # P-DCS-LAES # P-DCS-OSPS # P-DCS-Redirect
# P-DCS-Trace-Party-ID # P-Early-Media # P-Media-Authorization # P-Preferred-Identity # P-Preferred-Service # P-Profile-Key
# P-Refused-URI-List # P-Served-User # P-User-Database # P-Visited-Network-ID #
Last update: January 3, 2011
P-Access-Network-Info   RFC 3455 Up
P-Access-Network-Info  = "P-Access-Network-Info" HCOLON access-net-spec
access-net-spec= access-type *( SEMI access-info )
access-type= "IEEE-802.11a" / "IEEE-802.11b" / "3GPP-GERAN" / "3GPP-UTRAN-FDD"
/ "3GPP-UTRAN-TDD" / "3GPP-CDMA2000" / token
access-info= cgi-3gpp / utran-cell-id-3gpp / extension-access-info
extension-access-info= gen-value
cgi-3gpp= "cgi-3gpp" EQUAL (token / quoted-string)
utran-cell-id-3gpp= "utran-cell-id-3gpp" EQUAL (token / quoted-string)
 
P-Answer-State   RFC 4964 Up
P-Answer-State= "P-Answer-State" HCOLON answer-type
*(SEMI generic-param)
answer-type= "Confirmed" / "Unconfirmed" / token
 
P-Asserted-Identity   RFC 3325 Up
PAssertedID= "P-Asserted-Identity" HCOLON PAssertedID-value
*(COMMA PAssertedID-value)
; examples:
;    P-Asserted-Identity: "Cullen Jennings" <sip:fluffy@cisco.com>
;    P-Asserted-Identity: tel:+14085264000
PAssertedID-value= name-addr / addr-spec
 
P-Asserted-Service   RFC 6050 Up
PAssertedService= "P-Asserted-Service" HCOLON PAssertedService-value
PAssertedService-value= Service-ID *(COMMA Service-ID)
Service-ID= "urn:urn-7:" urn-service-id
urn-service-id= top-level *("." sub-service-id)
top-level= let-dig [ *26let-dig ]
sub-service-id= let-dig [ *let-dig ]
let-dig= ALPHA / DIGIT / "-"
 
P-Associated-URI   RFC 3455 Up
P-Associated-URI= "P-Associated-URI" HCOLON p-aso-uri-spec
*(COMMA p-aso-uri-spec)
p-aso-uri-spec= name-addr *( SEMI ai-param )
ai-param= generic-param
 
P-Called-Party-ID   RFC 3455 Up
P-Called-Party-ID= "P-Called-Party-ID" HCOLON called-pty-id-spec
; example:
;    P-Called-Party-ID: sip:user1-business@example.com
called-pty-id-spec= name-addr *( SEMI cpid-param )
cpid-param= generic-param
 
P-Charging-Function-Addresses   RFC 3455 Up
P-Charging-Addr= "P-Charging-Function-Addresses" HCOLON charge-addr-params
*( SEMI charge-addr-params )
; example:
;    P-Charging-Function-Addresses: ccf=192.1.1.1; ccf=192.1.1.2
charge-addr-params= ccf / ecf / generic-param
ccf= "ccf" EQUAL gen-value
ecf= "ecf" EQUAL gen-value
 
P-Charging-Vector   RFC 3455 Up
P-Charging-Vector= "P-Charging-Vector" HCOLON icid-value
*( SEMI charge-params )
; example:
;    P-Charging-Vector: icid-value=1234bc9876e;
;      icid-generated-at=192.0.6.8; orig-ioi=home1.net
charge-params= icid-gen-addr / orig-ioi / term-ioi / generic-param
icid-value= "icid-value" EQUAL gen-value
icid-gen-addr= "icid-generated-at" EQUAL host
orig-ioi= "orig-ioi" EQUAL gen-value
term-ioi= "term-ioi" EQUAL gen-value
 
P-DCS-Billing-Info   RFC 5503 Up
P-DCS-Billing-Info= "P-DCS-Billing-Info" HCOLON Billing-Correlation-ID "/" FEID
*( SEMI Billing-Info-param )
Billing-Correlation-ID= 1*48(HEXDIG)
FEID= 1*16(HEXDIG) "@" host
Billing-Info-param= RKS-Group-ID-param / Charge-param / Calling-param / Called-param
/ Routing-param / Loc-Routing-param / JIP-param / generic-param
RKS-Group-ID-param  = "rksgroup" EQUAL RKS-Group-ID
RKS-Group-ID= token
Charge-param= "charge" EQUAL Acct-Charge-URI
Acct-Charge-URI= LDQUOT addr-spec RDQUOT
Calling-param= "calling" EQUAL Acct-Calling-URI
Acct-Calling-URI= LDQUOT addr-spec RDQUOT
Called-param= "called" EQUAL Acct-Called-URI
Acct-Called-URI= LDQUOT addr-spec RDQUOT
Routing-param= "routing" EQUAL Acct-Routing-URI
Acct-Routing-URI= LDQUOT addr-spec RDQUOT
Loc-Routing-param= "locroute" EQUAL Acct-Loc-Routing-URI
Acct-Loc-Routing-URI= LDQUOT addr-spec RDQUOT
JIP-param= "jip" EQUAL jip
jip= LDQUOT 1*phonedigit-hex jip-context RDQUOT
jip-context= ";jip-context=" jip-descriptor
jip-descriptor= global-hex-digits
global-hex-digits= "+" 1*3(phonedigit) *phonedigit-hex
phonedigit= DIGIT / [ visual-separator ]
phonedigit-hex= HEXDIG / "*" / "#" / [ visual-separator ]
visual-separator= "-" / "." / "(" / ")"
 
P-DCS-LAES   RFC 5503 Up
P-DCS-LAES= "P-DCS-LAES" HCOLON Laes-sig
*( SEMI Laes-param )
Laes-sig= hostport
Laes-param= Laes-content / Laes-cccid / Laes-bcid / generic-param
Laes-content= "content" EQUAL hostport
Laes-cccid= "cccid" EQUAL 1*8(HEXDIG)
Laes-bcid = "cccid" EQUAL 1*48(HEXDIG)
 
P-DCS-OSPS   RFC 5503 Up
P-DCS-OSPS= "P-DCS-OSPS" HCOLON OSPS-Tag
OSPS-Tag= "BLV" / "EI" / "RING" / token
 
P-DCS-Redirect   RFC 5503 Up
P-DCS-Redirect= "P-DCS-Redirect" HCOLON Called-ID
*(SEMI redir-params)
Called-ID= LDQUOT addr-spec RDQUOT
redir-params= redir-uri-param / redir-count-param / generic-param
redir-uri-param= "redirector-uri" EQUAL Redirector
Redirector= LDQUOT addr-spec RDQUOT
redir-count-param= "count" EQUAL Redir-count
Redir-count= 1*DIGIT
 
P-DCS-Trace-Party-ID   RFC 5503 Up
P-DCS-Trace-Party-ID  = "P-DCS-Trace-Party-ID" HCOLON name-addr
*1(SEMI timestamp-param) *(SEMI trace-param)
timestamp-param= "timestamp=" 1*DIGIT ["." 1*DIGIT]
trace-param= generic-param
 
P-Early-Media   RFC 5009 Up
P-Early-Media= "P-Early-Media" HCOLON
[ em-param *(COMMA em-param) ]
em-param= "sendrecv" / "sendonly" / "recvonly"
/ "inactive" / "gated" / "supported" / token
 
P-Media-Authorization   RFC 3313 Up
P-Media-Authorization= "P-Media-Authorization" HCOLON P-Media-Authorization-Token
*(COMMA P-Media-Authorization-Token)
P-Media-Authorization-Token = 1*HEXDIG
 
P-Preferred-Identity   RFC 3325 Up
PPreferredID= "P-Preferred-Identity" HCOLON PPreferredID-value
*(COMMA PPreferredID-value)
; example:
;    P-Preferred-Identity: "Cullen Jennings" <sip:fluffy@cisco.com>
PPreferredID-value= name-addr / addr-spec
 
P-Preferred-Service   RFC 6050 Up
PPreferredService= "P-Preferred-Service" HCOLON PPreferredService-value
PPreferredService-value= Service-ID *(COMMA Service-ID)
 
P-Profile-Key   RFC 5002 Up
P-Profile-Key= "P-Profile-Key" HCOLON (name-addr / addr-spec)
*(SEMI generic-param)
; example:
;    P-Profile-Key: <sip:chatroom-!.*!@example.com>
 
P-Refused-URI-List   RFC 5318 Up
P-Refused-URI-List= "P-Refused-URI-List" HCOLON uri-list-entry *(COMMA uri-list-entry)
uri-list-entry= ( name-addr / addr-spec ) *(SEMI refused-param)
refused-param= members-param / generic-param
members-param= "members" EQUAL LDQUOT *( qdtext / quoted-pair ) RDQUOT
 
P-Served-User   RFC 5502 Up
P-Served-User= "P-Served-User" HCOLON PServedUser-value *(served-user-param)
served-user-param= sessioncase-param / registration-state-param / generic-param
PServedUser-value= name-addr / addr-spec
sessioncase-param= "sescase" EQUAL "orig" / "term"
registration-state-param= "regstate" EQUAL "unreg" / "reg"
 
P-User-Database   RFC 4457 Up
P-User-Database= "P-User-Database" HCOLON database *(SEMI generic-param)
database= LAQUOT DiameterURI RAQUOT
; example:
;    P-User-Database: <aaa://host.example.com;transport=tcp>
 
P-Visited-Network-ID   RFC 3455 Up
P-Visited-Network-ID= "P-Visited-Network-ID" HCOLON vnetwork-spec
*(COMMA vnetwork-spec)
; example:
;    P-Visited-Network-ID: other.net, "Visited network number 1"
vnetwork-spec= (token / quoted-string) *( SEMI vnetwork-param )
vnetwork-param= generic-param
 
Last update: January 3, 2011 
© 2005-2011 Joël Repiquet, All Rights Reserved.