a portal for promoting standardization knowledge

 
  IETF map Home
# SIP RFC3261's Example  
# SIP Protocol Structure
# SIP Dialogs & Routing
# SIP Service Examples
 01.Call Hold
 02.Consultation Hold
 03.Music On Hold
 04.Transfer: Unattended
 05.Transfer: Attended
 06.Transfer: Instant Messaging
 07.Call Forwarding Unconditional
 08.Call Forwarding Busy
 09.Call Forwarding No Answer
 10.3-Way Conf: 3rd Party Added
 11.3-Way Conf: 3rd Party Joins
 12.Find-Me
 13.Incoming Call Screening
 14.Outgoing Call Screening
 15.Call Park
 16.Call Pickup
 17.Automatic Redial
 18.Click to Dial
# ABNF Grammars
  - SIP Messages & URIs
  - SIP Headers
  - SIP Private Headers
  - SDP
  - URI Generic Syntax
  - ABNF Notation & Rules
# Cryptography Basics

ABNF Grammars
SIP Headers

Top SIP Headers  Header's Common Rules  Per-RFC Header Lists

SIP Header Fields
# Accept # Accept-Contact # Accept-Encoding # Accept-Language # Accept-Resource-Priority # Alert-Info # Allow # Allow-Events
# Answer-Mode # Authentication-Info # Authorization # Call-ID # Call-Info # Contact # Content-Disposition # Content-Encoding
# Content-Language # Content-Length # Content-Type # CSeq # Date # Error-Info # Event # Expires # Flow-Timer # From
# History-Info # Identity # Identity-Info # In-Reply-To # Join # Max-Breadth # Max-Forwards # MIME-Version # Min-Expires # Min-SE
# Organization # Path # Permission-Missing # Priority # Privacy # Priv-Answer-Mode # Proxy-Authenticate # Proxy-Authorization
# Proxy-Require # RAck # Reason # Record-Route # Refer-Sub # Refer-To # Referred-By # Reject-Contact # Replaces # Reply-To
# Request-Disposition # Require # Resource-Priority # Retry-After # Route # RSeq # Security-Client # Security-Server # Security-Verify
# Server # Service-Route # Session-Expires # SIP-ETag # SIP-If-Match # Subject # Subscription-State # Supported # Suppress-If-Match
# Target-Dialog # Timestamp # To # Trigger-Consent # Unsupported # User-Agent # Via # Warning # WWW-Authenticate #
Last update: January 3, 2011
Accept   RFC 3261 Up
Accept= "Accept" HCOLON [ accept-range *(COMMA accept-range) ]
; example:
;    Accept: application/dialog-info+xml
accept-range= media-range *(SEMI accept-param)
media-range= ( "*/*" / ( m-type SLASH "*" ) / ( m-type SLASH m-subtype ) )
*( SEMI m-parameter )
 
Accept-Contact / a   RFC 3841 Up
Accept-Contact= ( "Accept-Contact" / "a" ) HCOLON ac-value *(COMMA ac-value)
; examples:
;    Accept-Contact: *;audio;require
;    Accept-Contact: *;video;explicit
;    Accept-Contact: *;methods="BYE";class="business";q=1.0
ac-value= "*" *(SEMI ac-params)
ac-params= feature-param / req-param / explicit-param / generic-param
req-param= "require"
explicit-param= "explicit"
 
Accept-Encoding   RFC 3261 Up
Accept-Encoding= "Accept-Encoding" HCOLON [ encoding *(COMMA encoding) ]
; example:
;    Accept-Encoding: gzip
encoding= codings *(SEMI accept-param)
codings= content-coding / "*"
 
Accept-Language   RFC 3261 Up
Accept-Language= "Accept-Language" HCOLON [ language *(COMMA language) ]
; example:
;    Accept-Language: da, en-gb;q=0.8, en;q=0.7
language= language-range *(SEMI accept-param)
language-range= ( ( 1*8ALPHA *( "-" 1*8ALPHA ) ) / "*" )
 
Accept-Resource-Priority   RFC 4412 Up
Accept-Resource-Priority= "Accept-Resource-Priority" HCOLON [r-value *(COMMA r-value)]
; example:
;    Accept-Resource-Priority: dsn.flash-override,
;     dsn.flash, dsn.immediate, dsn.priority, dsn.routine
 
Alert-Info   RFC 3261 Up
Alert-Info= "Alert-Info" HCOLON alert-param *(COMMA alert-param)
; example:
;    Alert-Info: <http://www.example.com/sounds/moo.wav>
alert-param= LAQUOT absoluteURI RAQUOT *( SEMI generic-param )
 
Allow   RFC 3261 Up
Allow= "Allow" HCOLON [Method *(COMMA Method)]
; example:
;    Allow: INVITE, ACK, CANCEL, OPTIONS, BYE, REFER, NOTIFY
 
Allow-Events / u   RFC 3265 Up
Allow-Events= ( "Allow-Events" / "u" ) HCOLON event-type
*(COMMA event-type)
; example:
;    Allow-Events: spirits-INDPs
 
Answer-Mode   RFC 5373 Up
Answer-Mode= "Answer-Mode" HCOLON answer-mode-value *(SEMI answer-mode-param)
; example:
;    Answer-Mode: Manual
answer-mode-value= "Manual" / "Auto" / token
answer-mode-param= "require" / generic-param
 
Authentication-Info   RFC 3261 Up
Authentication-Info= "Authentication-Info" HCOLON ainfo *(COMMA ainfo)
; example:
;    Authentication-Info: nextnonce="47364c23432d2e131a5fb210812c"
ainfo= nextnonce / message-qop / response-auth / cnonce / nonce-count
nextnonce= "nextnonce" EQUAL nonce-value
response-auth= "rspauth" EQUAL response-digest
response-digest= LDQUOT *LHEX RDQUOT
 
Authorization   RFC 3261    RFC 3310 Up
Authorization= "Authorization" HCOLON credentials
; example:
;    Authorization: Digest username="bob", realm="atlanta.example.com"
;      nonce="ea9c8e88df84f1cec4341ae6cbe5a359", opaque="",
;      uri="sips:ss2.biloxi.example.com",
;      response="dfe56131d1958046689d83306477ecc"
credentials= ("Digest" LWS digest-response) / other-response
digest-response= dig-resp *(COMMA dig-resp)
dig-resp= username / realm / nonce / digest-uri / dresponse / algorithm / cnonce
/ opaque / message-qop / nonce-count / auth-param / auts
username= "username" EQUAL username-value
username-value= quoted-string
digest-uri= "uri" EQUAL LDQUOT digest-uri-value RDQUOT
digest-uri-value= request-uri
; equal to request-uri as specified by HTTP/1.1
message-qop= "qop" EQUAL qop-value
cnonce= "cnonce" EQUAL cnonce-value
cnonce-value= nonce-value
nonce-count= "nc" EQUAL nc-value
nc-value= 8LHEX
dresponse= "response" EQUAL request-digest
request-digest= LDQUOT 32LHEX RDQUOT
 
auth-param= auth-param-name EQUAL ( token / quoted-string )
auth-param-name= token
 
other-response= auth-scheme LWS auth-param *(COMMA auth-param)
auth-scheme= token
auts= "auts" EQUAL auts-param
auts-param= LDQUOT auts-value RDQUOT
auts-value= <base64 encoding of AUTS>
 
Call-ID / i   RFC 3261 Up
Call-ID= ( "Call-ID" / "i" ) HCOLON callid
; example:
;    Call-ID: 3848276298220188511@atlanta.example.com
 
Call-Info   RFC 3261    RFC 5367 Up
Call-Info= "Call-Info" HCOLON info *(COMMA info)
; example:
;    Call-Info: <http://wwww.example.com/alice/photo.jpg> ;purpose=icon,
;      <http://www.example.com/alice/> ;purpose=info
info= LAQUOT absoluteURI RAQUOT *( SEMI info-param )
info-param= ( "purpose" EQUAL ( "icon" / "info" / "card" / "list-management" / token ) )
/ generic-param
 
Contact / m   RFC 3261     RFC 3840     RFC 5626     RFC 5627 Up
Contact= ( "Contact" / "m" ) HCOLON
( STAR / (contact-param *(COMMA contact-param)))
; example:
;    Contact: <sip:bob@client.biloxi.example.com;transport=tcp>
contact-param= (name-addr / addr-spec) *( SEMI contact-params)
contact-params= c-p-q / c-p-expires / feature-param / temp-gruu / pub-gruu / c-p-reg / c-p-instance
/ contact-extension
 
c-p-q= "q" EQUAL qvalue
c-p-expires= "expires" EQUAL delta-seconds
; example:
;    Contact: "Mr. Watson" <sip:watson@worcester.bell-telephone.com>
;        ;q=0.7; expires=3600,
;      "Mr. Watson" <mailto:watson@bell-telephone.com>
;        ;q=0.1
 
feature-param= enc-feature-tag [ EQUAL   LDQUOT   (tag-value-list   /   string-value)   RDQUOT ]
enc-feature-tag= base-tags / other-tags
base-tags= "audio" / "automata" / "class" / "duplex" / "data" / "control"
/ "mobility" / "description" / "events" / "priority" / "methods"
/ "schemes" / "application" / "video" / "language" / "type"
/ "isfocus" / "actor" / "text" / "extensions"
 
other-tags= "+"   ftag-name
ftag-name= ALPHA *( ALPHA / DIGIT / "!" / "'" / "." / "-" / "%" )
; e.g.
; "+sip.byeless" and "+sip.rendering" as defined in [RFC 4235]
; "+sip.message" as defined in [RFC 4569]
; "+sip.instance" as defined in [RFC 5627]
 
tag-value-list= tag-value *("," tag-value)
tag-value= ["!"] (token-nobang / boolean / numeric)
token-nobang= 1*( alphanum / "-" / "." / "%" / "*" / "_" / "+" / "`" / "'" / "~" )
boolean= "TRUE" / "FALSE"
numeric= "#" numeric-relation number
numeric-relation= ">=" / "<=" / "=" / (number ":")
number= [ "+" / "-" ] 1*DIGIT ["." 0*DIGIT]
 
string-value= "<" *(qdtext-no-abkt / quoted-pair ) ">"
qdtext-no-abkt= LWS / %x21 / %x23-3B / %x3D / %x3F-5B / %x5D-7E / UTF8-NONASCII
 
temp-gruu= "temp-gruu" EQUAL LDQUOT *( qdtext / quoted-pair ) RDQUOT
pub-gruu= "pub-gruu" EQUAL LDQUOT *( qdtext / quoted-pair ) RDQUOT
 
c-p-reg= "" EQUAL 1*DIGIT
; 1 to (2^31 - 1)
 
c-p-instance= "+sip.instance" EQUAL LDQUOT "<" instance-val ">" RDQUOT
instance-val= *uric
; UUID as defined in [RFC 4122]
 
contact-extension= generic-param
 
Content-Disposition   RFC 3261 Up
Content-Disposition= "Content-Disposition" HCOLON disp-type *( SEMI disp-param )
; example:
;    Content-Disposition: session;handling=optional
disp-type= "render" / "session" / "icon" / "alert"
/ "aib" / "early-session" / disp-extension-token
; "aib" is defined in [ RFC3893]
; "early-session" is defined in [ RFC3959]
disp-param= handling-param / generic-param
handling-param= "handling" EQUAL ( "optional" / "required" / other-handling )
other-handling= token
disp-extension-token= token
 
Content-Encoding / e   RFC 3261 Up
Content-Encoding= ( "Content-Encoding" / "e" ) HCOLON content-coding
*(COMMA content-coding)
; example:
;    Content-Encoding: gzip
content-coding= token
 
Content-Language   RFC 3261 Up
Content-Language= "Content-Language" HCOLON language-tag
*(COMMA language-tag)
; example:
;    Content-Language: fr
language-tag= primary-tag *( "-" subtag )
primary-tag= 1*8ALPHA
subtag= 1*8ALPHA
 
Content-Length / l   RFC 3261 Up
Content-Length= ( "Content-Length" / "l" ) HCOLON 1*DIGIT
; example:
;    Content-Length: 0
 
Content-Type / c   RFC 3261 Up
Content-Type= ( "Content-Type" / "c" ) HCOLON media-type
; example:
;    Content-Type: application/sdp
media-type= m-type SLASH m-subtype *( SEMI m-parameter)
m-type= discrete-type / composite-type
discrete-type= "text" / "image" / "audio" / "video" / "application" / extension-token
composite-type= "message" / "multipart" / extension-token
extension-token= ietf-token / x-token
ietf-token= token
x-token= "x-" token
m-subtype= extension-token / iana-token
iana-token= token
m-parameter= m-attribute EQUAL m-value
m-attribute= token
m-value= token / quoted-string
 
CSeq   RFC 3261 Up
CSeq= "CSeq" HCOLON 1*DIGIT LWS Method
; example:
;    CSeq: 1 INVITE
 
Date   RFC 3261 Up
Date= "Date" HCOLON SIP-date
; example:
;    Date: Thu, 21 Feb 2002 13:02:03 GMT
SIP-date= rfc1123-date
rfc1123-date= wkday "," SP date1 SP time SP "GMT"
date1= 2DIGIT SP month SP 4DIGIT
; day month year (e.g., 02 Jun 1982)
time= 2DIGIT ":" 2DIGIT ":" 2DIGIT
; 00:00:00 - 23:59:59
wkday= "Mon" / "Tue" / "Wed" / "Thu" / "Fri" / "Sat" / "Sun"
month= "Jan" / "Feb" / "Mar" / "Apr" / "May" / "Jun"
/ "Jul" / "Aug" / "Sep" / "Oct" / "Nov" / "Dec"
 
Error-Info   RFC 3261 Up
Error-Info= "Error-Info" HCOLON error-uri *(COMMA error-uri)
; example:
;    Error-Info: <sips:screen-failure-term-ann@annoucement.example.com>
error-uri= LAQUOT absoluteURI RAQUOT *( SEMI generic-param )
 
Event / o   RFC 3265 Up
Event= ( "Event" / "o" ) HCOLON event-type *( SEMI event-param )
; example:
;    Event: refer
event-type= event-package *( "." event-template )
event-package= token-nodot
event-template= token-nodot
token-nodot= 1*( alphanum / "-" / "!" / "%" / "*" / "_" / "+" / "`" / "'" / "~" )
event-param= generic-param / ( "id" EQUAL token )
/ call-ident / from-tag / to-tag / with-sessd
; defined in [ RFC4235]
call-ident= "call-id" EQUAL ( token / DQUOTE callid DQUOTE )
; NOTE: any DQUOTEs inside callid MUST be escaped!
with-sessd= "include-session-description"
 
Expires   RFC 3261 Up
Expires= "Expires" HCOLON delta-seconds
; example:
;    Expires: 7200
 
Flow-Timer   RFC 5626 Up
Flow-Timer= "Flow-Timer" HCOLON 1*DIGIT
; example:
;    Flow-Timer: 120
 
From / f   RFC 3261 Up
From= ( "From" / "f" ) HCOLON from-spec
; examples:
;    From: Alice <sip:alice@atlanta.example.com>;tag=9fxced76sl
;    From: "Anonymous" <sip:anonymous@anonymous.invalid>;tag=1928301774
from-spec= ( name-addr / addr-spec ) *( SEMI from-param )
from-param= tag-param / generic-param
tag-param= "tag" EQUAL token
 
History-Info   RFC 4244 Up
History-Info= "History-Info" HCOLON hi-entry *(COMMA hi-entry)
; example:
;    History-Info:<sip:UserA@ims.example.com?Reason=SIP%3B\
;      cause%3D302>;index=1;foo=bar
hi-entry= hi-targeted-to-uri *( SEMI hi-param )
hi-targeted-to-uri= name-addr
hi-param= hi-index / hi-extension
hi-index= "index" EQUAL 1*DIGIT *("." 1*DIGIT)
hi-extension= generic-param
 
Identity / y   RFC 4474 Up
Identity= "Identity" HCOLON signed-identity-digest
signed-identity-digest= LDQUOT 32LHEX RDQUOT
 
Identity-Info / n   RFC 4474 Up
Identity-Info= "Identity-Info" HCOLON ident-info *( SEMI ident-info-params )
ident-info= LAQUOT absoluteURI RAQUOT
ident-info-params= ident-info-alg / ident-info-extension
ident-info-alg= "alg" EQUAL token
ident-info-extension= generic-param
 
In-Reply-To   RFC 3261 Up
In-Reply-To= "In-Reply-To" HCOLON callid *(COMMA callid)
; example:
;    In-Reply-To: 70710@saturn.bell-tel.com, 17320@saturn.bell-tel.com
 
Join   RFC 3911 Up
Join= "Join" HCOLON callid *(SEMI join-param)
; example:
;    Join: 12345600@atlanta.example.com;from-tag=1234567;to-tag=23431
join-param= to-tag / from-tag / generic-param
to-tag= "to-tag" EQUAL token
from-tag= "from-tag" EQUAL token
 
Max-Breadth   RFC 5393 Up
Max-Breadth= "Max-Breadth" HCOLON 1*DIGIT
 
Max-Forwards   RFC 3261 Up
Max-Forwards= "Max-Forwards" HCOLON 1*DIGIT
; example:
;    Max-Forwards: 69
 
MIME-Version   RFC 3261 Up
MIME-Version= "MIME-Version" HCOLON 1*DIGIT "." 1*DIGIT
; example:
;    MIME-Version: 1.0
 
Min-Expires   RFC 3261 Up
Min-Expires= "Min-Expires" HCOLON delta-seconds
; example:
;    Min-Expires: 60
 
Min-SE   RFC 4028 Up
Min-SE= "Min-SE" HCOLON delta-seconds *(SEMI generic-param)
; example:
;    Min-SE: 3600
 
Organization   RFC 3261 Up
Organization= "Organization" HCOLON [TEXT-UTF8-TRIM]
; example:
;    Organization: Boxes by Bob
 
Path   RFC 3327 Up
Path= "Path" HCOLON path-value *(COMMA path-value)
; example:
;    Path: <sip:P3.EXAMPLEHOME.COM;lr>,<sip:P1.EXAMPLEVISITED.COM;lr>
path-value= name-addr *( SEMI rr-param )
 
Permission-Missing   RFC 5360 Up
Permission-Missing= "Permission-Missing" HCOLON per-miss-spec *(COMMA per-miss-spec)
; example:
;    Permission-Missing: sip:C@example.com
per-miss-spec= ( name-addr / addr-spec ) *( SEMI generic-param )
 
Priority   RFC 3261 Up
Priority= "Priority" HCOLON priority-value
; example:
;    Priority: emergency
priority-value= "emergency" / "urgent" / "normal" / "non-urgent" / other-priority
other-priority= token
 
Privacy   RFC 3323 RFC 3325 Up
Privacy-hdr= "Privacy" HCOLON priv-value *(";" priv-value)
; example:
;    Privacy: id
priv-value= "header" / "session" / "user" / "none" / "critical" / "id" / "history" / token
; 'id' is defined in RFC 3325
 
Priv-Answer-Mode   RFC 5373 Up
Priv-Answer-Mode= "Priv-Answer-Mode" HCOLON answer-mode-value *(SEMI answer-mode-param)
; example:
;    Priv-Answer-Mode: Auto
 
Proxy-Authenticate   RFC 3261 Up
Proxy-Authenticate= "Proxy-Authenticate" HCOLON challenge
; example:
;    Proxy-Authenticate: Digest realm="atlanta.example.com", qop="auth",
;      nonce="f84f1cec41e6cbe5aea9c8e88d359",
;      opaque="", stale=FALSE, algorithm=MD5
challenge= ("Digest" LWS digest-cln *(COMMA digest-cln)) / other-challenge
other-challenge= auth-scheme / auth-param *(COMMA auth-param)
digest-cln= realm / domain / nonce / opaque / stale / algorithm
/ qop-options / auth-param
realm= "realm" EQUAL realm-value
realm-value= quoted-string
domain= "domain" EQUAL LDQUOT URI *( 1*SP URI ) RDQUOT
URI= absoluteURI / abs-path
opaque= "opaque" EQUAL quoted-string
stale= "stale" EQUAL ( "true" / "false" )
qop-options= "qop" EQUAL LDQUOT qop-value *("," qop-value) RDQUOT
qop-value= "auth" / "auth-int" / token
 
Proxy-Authorization   RFC 3261 Up
Proxy-Authorization= "Proxy-Authorization" HCOLON credentials
; example:
;    Proxy-Authorization: Digest username="alice",
;      realm="atlanta.example.com",
;      nonce="wf84f1ceczx41ae6cbe5aea9c8e88d359", opaque="",
;      uri="sip:bob@biloxi.example.com",
;      response="42ce3cef44b22f50c6a6071bc8"
 
Proxy-Require   RFC 3261 Up
Proxy-Require= "Proxy-Require" HCOLON option-tag *(COMMA option-tag)
; example:
;    Proxy-Require: sec-agree
 
RAck   RFC 3262 Up
RAck= "RAck" HCOLON response-num LWS CSeq-num LWS Method
; example:
;    RAck: 776656 1 INVITE
response-num= 1*DIGIT
CSeq-num= 1*DIGIT
 
Reason   RFC 3326    RFC 4411 Up
Reason= "Reason" HCOLON reason-value *(COMMA reason-value)
; examples:
;    Reason: SIP ;cause=200 ;text="Call completed elsewhere"
;    Reason: Q.850 ;cause=16 ;text="Terminated"
;    Reason: SIP ;cause=600 ;text="Busy Everywhere"
;    Reason: SIP ;cause=580 ;text="Precondition Failure"
reason-value= protocol *(SEMI reason-params)
protocol= "SIP" / "Q.850" / "Preemption" / token
reason-params= protocol-cause / reason-text / reason-extension
protocol-cause= "cause" EQUAL "cause
cause= 1*DIGIT
reason-text= "text" EQUAL quoted-string
reason-extension= generic-param
 
Record-Route   RFC 3261 Up
Record-Route= "Record-Route" HCOLON rec-route *(COMMA rec-route)
; example:
;    Record-Route: <sip:ss2.biloxi.example.com;lr>,
;     <sip:ss1.atlanta.example.com;lr>
rec-route= name-addr *( SEMI rr-param )
rr-param= generic-param
 
Refer-Sub   RFC 4488 Up
Refer-Sub= "Refer-Sub" HCOLON refer-sub-value *(SEMI exten)
refer-sub-value= "true" / "false"
exten= generic-param
 
Refer-To / r   RFC 3515    RFC 4508 Up
Refer-To= ( "Refer-To" / "r" ) HCOLON ( name-addr / addr-spec )
*(SEMI refer-param)
refer-param= generic-param / feature-param
; example:
;    Refer-To: <sips:a8342043f@atlanta.example.com?Replaces=
;      12345601%40atlanta.example.com%3Bfrom-tag%3D314159%3Bto-tag%3D1234567>
;    Refer-To: sip:conf44@example.com;isfocus
 
Referred-By / b   RFC 3892 Up
Referred-By= ( "Referred-By" / "b" ) HCOLON referrer-uri
*( SEMI (referredby-id-param / generic-param) )
; example:
;    Referred-By: <sip:referrer@referrer.example>
;      ;cid="20398823.2UWQFN309shb3@referrer.example"
referrer-uri= ( name-addr / addr-spec )
referredby-id-param= "cid" EQUAL sip-clean-msg-id
sip-clean-msg-id= LDQUOT dot-atom "@" (dot-atom / host) RDQUOT
dot-atom= atom *( "." atom )
atom= 1*( alphanum / "-" / "!" / "%" / "*" / "_" / "+" / "'" / "`" / "~" )
 
Reject-Contact / j   RFC 3841 Up
Reject-Contact= ( "Reject-Contact" / "j" ) HCOLON rc-value *(COMMA rc-value)
; example:
;    Reject-Contact: *;actor="msg-taker";video
rc-value= "*" *(SEMI rc-params)
rc-params= feature-param / generic-param
 
Replaces   RFC 3891 Up
Replaces= "Replaces" HCOLON callid *(SEMI replaces-param)
; example:
;    Replaces: 425928@bobster.example.org;to-tag=7743;from-tag=6472
replaces-param= to-tag / from-tag / early-flag / generic-param
to-tag= "to-tag" EQUAL token
from-tag= "from-tag" EQUAL token
early-flag= "early-only"
 
Reply-To   RFC 3261 Up
Reply-To= "Reply-To" HCOLON rplyto-spec
; example:
;    Reply-To: Bob <sip:bob@biloxi.com>
rplyto-spec= ( name-addr / addr-spec ) *( SEMI rplyto-param )
rplyto-param= generic-param
 
Request-Disposition / d   RFC 3841 Up
Request-Disposition= ( "Request-Disposition" / "d" ) HCOLON directive
*(COMMA directive)
; example:
;    Request-Disposition: proxy, recurse, parallel
directive= proxy-directive / cancel-directive / fork-directive
/ recurse-directive / parallel-directive / queue-directive
proxy-directive= "proxy" / "redirect"
cancel-directive= "cancel" / "no-cancel"
fork-directive= "fork" / "no-fork"
recurse-directive= "recurse" / "no-recurse"
parallel-directive= "parallel" / "sequential"
queue-directive= "queue" / "no-queue"
 
Require   RFC 3261 Up
Require= "Require" HCOLON option-tag *(COMMA option-tag)
; example:
;    Require: 100rel
 
Resource-Priority   RFC 4412 Up
Resource-Priority= "Resource-Priority" HCOLON r-value *(COMMA r-value)
; example:
;    Resource-Priority: wps.3, dsn.flash
r-value= namespace "." r-priority
namespace= token-nodot
r-priority= token-nodot
token-nodot= 1*( alphanum / "-" / "!" / "%" / "*" / "_" / "+" / "`" / "'" / "~" )
 
Retry-After   RFC 3261 Up
Retry-After= "Retry-After" HCOLON delta-seconds [ comment ]
*( SEMI retry-param )
; examples:
;    Retry-After: 18000;duration=3600
;    Retry-After: 120 (I'm in a meeting)
retry-param= ("duration" EQUAL delta-seconds) / generic-param
 
Route   RFC 3261 Up
Route= "Route" HCOLON route-param *(COMMA route-param)
; example:
;    Route: <sip:ss1.atlanta.example.com;lr>,
;     <sip:ss2.biloxi.example.com;lr>
route-param= name-addr *( SEMI rr-param )
 
RSeq   RFC 3262 Up
RSeq= "RSeq" HCOLON response-num
; example:
;    RSeq: 988789
 
Security-Client   RFC 3329 Up
security-client= "Security-Client" HCOLON sec-mechanism
*(COMMA sec-mechanism)
; example:
;    Security-Client: digest
sec-mechanism= mechanism-name *( SEMI mech-parameters )
mechanism-name= ( "digest" / "tls" / "ipsec-ike" / "ipsec-man" / token )
mech-parameters= ( preference / digest-algorithm / digest-qop / digest-verify / extension )
preference= "q" EQUAL qvalue
digest-algorithm= "d-alg" EQUAL token
digest-qop= "d-qop" EQUAL token
digest-verify= "d-ver" EQUAL LDQUOT 32LHEX RDQUOT
extension= generic-param
 
Security-Server   RFC 3329 Up
security-server= "Security-Server" HCOLON sec-mechanism
*(COMMA sec-mechanism)
; example:
;    Security-Server: ipsec-ike;q=0.1
 
Security-Verify   RFC 3329 Up
security-verify= "Security-Verify" HCOLON sec-mechanism
*(COMMA sec-mechanism)
; example:
;    Security-Verify: tls;q=0.2
 
Server   RFC 3261 Up
Server= "Server" HCOLON server-val *(LWS server-val)
; example:
;    Server: HomeServer v2
server-val= product / comment
product= token [SLASH product-version]
product-version= token
 
Service-Route   RFC 3608 Up
Service-Route= "Service-Route" HCOLON sr-value
*(COMMA sr-value)
; example:
;    Service-Route: <sip:P2.HOME.EXAMPLE.COM;lr>,
;      <sip:HSP.HOME.EXAMPLE.COM;lr>
sr-value= name-addr *( SEMI rr-param )
 
Session-Expires / x   RFC 4028 Up
Session-Expires= ( "Session-Expires" / "x" ) HCOLON delta-seconds
*( SEMI (se-params )
; example:
;    Session-Expires: 4000;refresher=uac
se-params= refresher-param / generic-param
refresher-param= "refresher" EQUAL ("uas" / "uac")
 
SIP-ETag   RFC 3903 Up
SIP-ETag= "SIP-ETag" HCOLON entity-tag
; example:
;    SIP-ETag: dx200xyz
entity-tag= token
 
SIP-If-Match   RFC 3903 Up
SIP-If-Match= "SIP-If-Match" HCOLON entity-tag
; example:
;    SIP-If-Match: dx200xyz
 
Subject / s   RFC 3261 Up
Subject= ( "Subject" / "s" ) HCOLON [TEXT-UTF8-TRIM]
; example:
;    Subject: A tornado is heading our way!
 
Subscription-State   RFC 3265 Up
Subscription-State= ( "Subscription-State" / "o" ) HCOLON substate-value
*( SEMI subexp-params )
; example:
;    Subscription-State: active;expires=60
substate-value= "active" / "pending" / "terminated" / extension-substate
extension-substate= token
subexp-params= ("reason" EQUAL event-reason-value)
/ ("expires" EQUAL delta-seconds)
/ ("retry-after" EQUAL delta-seconds)
/ generic-param
event-reason-value= "deactivated" / "probation" / "rejected"
/ "timeout" / "giveup" / "noresource"
/ event-reason-extension
event-reason-extension = token
 
Supported / k   RFC 3261 Up
Supported= ( "Supported" / "k" ) HCOLON [option-tag *(COMMA option-tag)]
; example:
;    Supported: replaces
 
Suppress-If-Match   RFC 5839 Up
Suppress-If-Match= "Suppress-If-Match" HCOLON entity-tag
; example:
;    Suppress-If-Match: dx200xyz
 
Target-Dialog   RFC 4538 Up
Target-Dialog= "Target-Dialog" HCOLON callid *(SEMI td-param)
td-param= remote-param / local-param / generic-param
remote-param= "remote-tag" EQUAL token
local-param= "local-tag" EQUAL token
 
Timestamp   RFC 3261 Up
Timestamp= "Timestamp" HCOLON 1*(DIGIT) [ "." *(DIGIT) ] [ LWS delay ]
; example:
;    Timestamp: 54
delay= *(DIGIT) [ "." *(DIGIT) ]
 
To / t   RFC 3261 Up
To= ( "To" / "t" ) HCOLON ( name-addr / addr-spec )
*( SEMI to-param )
; example:
;    To: Bob <sip:bob@biloxi.example.com>;tag=8321234356
to-param= tag-param / generic-param
 
Trigger-Consent   RFC 5360 Up
Trigger-Consent= "Trigger-Consent" HCOLON trigger-cons-spec *(COMMA trigger-cons-spec)
; example:
;    Trigger-Consent: sip:123@relay.example.com
;      ;target-uri="sip:friends@relay.example.com"
trigger-cons-spec= ( SIP-URI / SIPS-URI ) *( SEMI trigger-param )
trigger-param= target-uri / generic-param
target-uri= "target-uri" EQUAL
LDQUOT *( qdtext / quoted-pair ) RDQUOT
 
Unsupported   RFC 3261 Up
Unsupported= "Unsupported" HCOLON option-tag *(COMMA option-tag)
; example:
;    Unsupported: 100rel
 
User-Agent   RFC 3261 Up
User-Agent= "User-Agent" HCOLON server-val *(LWS server-val)
; example:
;    User-Agent: Softphone Beta1.5
 
Via / v   RFC 3261    RFC 3486    RFC 3581 Up
Via= ( "Via" / "v" ) HCOLON via-parm *(COMMA via-parm)
; example:
;    Via: SIP/2.0/TCP client.atlanta.example.com:5060
;      ;branch=z9hG4bK74b76
;      ;received=192.0.2.101
via-parm= sent-protocol LWS sent-by *( SEMI via-params )
via-params= via-ttl / via-maddr / via-received / via-branch
/ via-compression / response-port / via-extension
via-ttl= "ttl" EQUAL ttl
via-maddr= "maddr" EQUAL host
via-received= "received" EQUAL (IPv4address / IPv6address)
via-branch= "branch" EQUAL token
via-compression= "comp" EQUAL ("sigcomp" / other-compression)
other-compression= token
response-port= "rport" [EQUAL 1*DIGIT]
via-extension= generic-param
sent-protocol= protocol-name SLASH protocol-version SLASH transport
protocol-name= "SIP" / token
protocol-version= token
transport= "UDP" / "TCP" / "TLS" / "SCTP" / "TLS-SCTP" / other-transport
; TLS-SCTP is defined in [ RFC4168]
sent-by= host [ COLON port ]
ttl= 1*3DIGIT   
; 0 to 255
 
Warning   RFC 3261 Up
Warning= "Warning" HCOLON warning-value *(COMMA warning-value)
; example:
;    Warning: 301 isi.edu "Incompatible network address type 'E.164'"
warning-value= warn-code SP warn-agent SP warn-text
warn-code= 3DIGIT
warn-agent= hostport / pseudonym
warn-text= quoted-string
pseudonym= token
 
WWW-Authenticate   RFC 3261 Up
WWW-Authenticate= "WWW-Authenticate" HCOLON challenge
; example:
;    WWW-Authenticate: Digest realm="atlanta.example.com", qop="auth",
;      nonce="84f1c1ae6cbe5ua9c8e88dfa3ecm3459",
;      opaque="", stale=FALSE, algorithm=MD5
 
Top SIP Headers  Header's Common Rules  Per-RFC Header Lists

Most common definitions in Header Fields
# accept-param # addr-spec # algorithm # callid # delta-seconds # generic-param # gen-value # name-addr # nonce
# option-tag # qvalue #
accept-param   Up
accept-param= ("q" EQUAL qvalue ) / generic-param
 
addr-spec   Up
addr-spec= SIP-URI / SIPS-URI / absoluteURI
 
algorithm   Up
algorithm= "algorithm" EQUAL ( aka-namespace / algorithm-value )
; algorithm rule is as amended by [RFC 3310]
; example:
;    algorithm=AKAv1-MD5
aka-namespace= aka-version "-" algorithm-value
aka-version= "AKAv" 1*DIGIT
algorithm-value= ( "MD5" / "MD5-sess" / token )
 
callid   Up
callid= word [ "@" word ]
 
delta-seconds   Up
delta-seconds= 1*DIGIT
 
generic-param   Up
generic-param= token [ EQUAL gen-value ]
gen-value= token / host / quoted-string
 
name-addr   Up
name-addr= [ display-name ] LAQUOT addr-spec RAQUOT
; example:
;    Bob <sip:bob@biloxi.example.com>
 
display-name= *(token LWS) / quoted-string
 
nonce   Up
nonce= "nonce" EQUAL ( aka-nonce / nonce-value )
; nonce rule is as amended by [RFC 3310]
; example:
;    nonce="MzQ0a2xrbGtmbGtsZm9wb2tsc2tqaHJzZXNy9uQyMzMzMzQK="
aka-nonce= LDQUOT aka-nonce-value RDQUOT
aka-nonce-value= <base64 encoding of RAND, AUTN, and server specific data>
nonce-value= quoted-string
 
option-tag   Up
option-tag= token
; Option tags are used in header fields such as Require, Supported, Proxy-Require,
; and Unsupported, in support of SIP compatibility mechanisms for extensions. The
; option tag itself is a string that is associated with a particular SIP option (that is,
; an extension). It identifies the option to SIP endpoints.
;
  ; 100rel [RFC 3262]
  ; precondition [RFC 3312]
  ; privacy [RFC 3323]
  ; path [RFC 3327]
  ; sec-agree [RFC 3329]
  ; pref [RFC 3840]
  ; replaces [RFC 3891]
  ; join [RFC 3911]
  ; early-session [RFC 3959]
  ; timer [RFC 4028]
  ; sdp-anat [RFC4092]
  ; histinfo [RFC 4244]
  ; resource-priority [RFC 4412]
  ; norefersub [RFC 4488]
  ; tdialog [RFC 4538]
  ; eventlist [RFC 4662]
  ; from-change [RFC 4916]
  ; recipient-list-message [RFC 5365]
  ; recipient-list-invite [RFC 5366]
  ; recipient-list-subscribe [RFC 5367]
  ; multiple-refer [RFC 5368]
  ; answermode [RFC 5373]
  ; outbound [RFC 5626]
  ; gruu [RFC 5627]
  ; ice [RFC 5768]
 
qvalue   Up
qvalue= ("0" [ "." 0*3DIGIT ] )
/ ( "1" [ "." 0*3("0") ] )
 
Top SIP Headers  Header's Common Rules  Per-RFC Header Lists

RFCs defining or modifying SIP Header Fields
RFC 3261: # Accept # Accept-Encoding # Accept-Language # Alert-Info # Allow # Authentication-Info
# Authorization (*) # Call-ID # Call-Info # Contact (*) # Content-Disposition # Content-Encoding
# Content-Language # Content-Length # Content-Type # CSeq # Date # Error-Info # Expires # From
# In-Reply-To # Max-Forwards # MIME-Version # Min-Expires # Organization # Priority
# Proxy-Authenticate # Proxy-Authorization # Proxy-Require # Record-Route # Reply-To # Require
# Retry-After # Route # Server # Subject # Supported # Timestamp # To # Unsupported # User-Agent
# Via (*) # Warning # WWW-Authenticate #
RFC 3262: # RAck # RSeq #
RFC 3265: # Allow-Events # Event # Subscription-State #
RFC 3310: # Authorization (*) #
RFC 3313: # P-Media-Authorization #
RFC 3323: # Privacy #
RFC 3325: # P-Asserted-Identity # P-Preferred-Identity #
RFC 3326: # Reason #
RFC 3327: # Path #
RFC 3329: # Security-Client # Security-Server # Security-Verify #
RFC 3455: # P-Access-Network-Info # P-Associated-URI # P-Called-Party-ID # P-Charging-Function-Addresses
# P-Charging-Vector # P-Visited-Network-ID #
RFC 3486: # Via (*) #
RFC 3515: # Refer-To (*) #
RFC 3581: # Via (*) #
RFC 3608: # Service-Route #
RFC 3840: # Contact (*) #
RFC 3841: # Accept-Contact # Reject-Contact # Request-Disposition #
RFC 3891: # Replaces #
RFC 3892: # Referred-By #
RFC 3903: # SIP-ETag # SIP-If-Match #
RFC 3911: # Join #
RFC 4028: # Min-SE # Session-Expires #
RFC 4244: # History-Info #
RFC 4412: # Accept-Resource-Priority # Resource-Priority #
RFC 4457: # P-User-Database #
RFC 4474: # Identity # Identity-Info #
RFC 4488: # Refer-Sub #
RFC 4508: # Refer-To (*) #
RFC 4538: # Target-Dialog #
RFC 4964: # P-Answer-State #
RFC 5002: # P-Profile-Key #
RFC 5009: # P-Early-Media #
RFC 5318: # P-Refused-URI-List #
RFC 5360: # Permission-Missing # Trigger-Consent #
RFC 5373: # Answer-Mode # Priv-Answer-Mode #
RFC 5393: # Max-Breadth #
RFC 5502: # P-Served-User #
RFC 5503: # P-DCS-Billing-Info # P-DCS-LAES # P-DCS-OSPS # P-DCS-Redirect # P-DCS-Trace-Party-ID #
RFC 5626: # Flow-Timer #
RFC 5839: # SIP-If-Match #
RFC 6050: # P-Asserted-Service # P-Preferred-Service #
Last update: January 3, 2011 
© 2005-2011 Joël Repiquet, All Rights Reserved.